• Учётная политика может меняться каждый день;
• Изменение Учётной политики фиксируется соответствующим документом;
• "Считается, что документы задним числом не вводятся, но старые документы могут проводиться неоперативно".
• Это единственная задача, в которой упоминается метод списания по средней;

Пойдем от простого к сложному:

• Самый простой - первый пункт. Нужно просто установить периодичность регистра сведений содержащего хронологию изменений учётной политики в пределах дня и всё!
• С документом, фиксирующим её изменения вроде бы тоже всё просто. Нужно его создать, и назначить регистратором вышеупомянутого регистра, для чего сам регистр нужно будет сделать зависимым от регистратора. Но это кажущаяся простота, мы ещё вернёмся к этому пункту позже, когда станет понятен его истинный смысл.
• Дальше нас ждёт весьма презабавная формулировочка: "Считается...", - которая рождает вполне естественный вопрос: "В каком смысле считается? В смысле того, что если кто-то введёт документ задним числом, для нас это станет полной неожиданностью?". И знаете, если бы это была реальная работа, я бы обязательно задал этот вопрос! Но мы на экзамене и вопросы задают нам, а мы отвечаем на свой страх и риск. Поэтому, коль скоро формулировка туманная, каждый сам для себя делает выбор:
• Не заморачиваться или
• Запретить!
• Как эффективно запретить ввод документов задним числом мы расскажем вам в задаче 6, поскольку там формулировка более конкретная: "нельзя"! А Вы между тем сможете определиться, какое решение больше импонирует Вам лично.
• И, наконец, последний пункт - списание по средней!

Вот он-то как раз особенный и, с аналитической точки зрения, самый сложный. Дело в том, что списание по средней, это уже не партионный учет!!! При списании по средней вы уже не можете указать с какой именно партии вы списываете товар. Поскольку цена во всех партиях потенциально разная, и может нигде не совпадать со средней ценой. Получается, что как только вы перейдёте на списание по средней, весь ваш партионный учет будет нарушен! И обратно восстановить его уже не удастся.

Но не будем сокрушаться об этом - "заказчик всегда прав". Наша задача собственно только в том и состоит, чтобы даже в таких условиях программа работала устойчиво, как ни в чём ни бывало, и не выдавала сообщений о системных ошибках. Ибо, когда программа тупо сбоит, программист в любом случае виноват. Даже если сбой вызван "наведённой ошибкой" [Заказчика при составлении ТЗ].

Главное, что мы для себя определили: переключение на списание по средней и обратно, это фактически отключение и включение партионного учета. И мы должны сделать это аккуратно без далеко идущих последствий.

Фактически, в момент перехода на списание по средней нам нужно избавиться от информации о партиях, так как в противном случае у нас:

• либо будут зависать остатки по партиям, если мы просто не укажем партию в расходе;
• либо будет происходить рассогласование количества и стоимости, если мы будем списывать с конкретной партии, но по цене, отличающейся от цены прихода.

На экзамене за любую из этих ошибок мы можем потерять драгоценные 2 балла из 5.

Вот тут-то и возникает необходимость в документе, упомянутом в третьем пункте, который оформляется как раз в момент перехода. Именно при проведении этого документа мы можем избавиться от партий, попросту свернув их. Нам нужно будет списать остатки по всем партиям в расход, и вновь поставить их на приход, но уже без указания партии.

И впредь, до перехода на списание по ЛИФО или ФИФО, больше не указывать их.

Из этого последнего замечания вытекает ещё одна особенность проведения документов, на этот раз, касающаяся приходной накладной. Прежде чем её провести, нам нужно знать, должна ли она указываться в качестве партии или нет. А для этого прежде нужно прочитать текущее значение учетной политики.

На экзамене за любую из этих ошибок мы можем потерять драгоценные 2 балла из 5.

Вот тут-то и возникает необходимость в документе, упомянутом в третьем пункте, который оформляется как раз в момент перехода. Именно при проведении этого документа мы можем избавиться от партий, попросту свернув их. Нам нужно будет списать остатки по всем партиям в расход, и вновь поставить их на приход, но уже без указания партии.

И впредь, до перехода на списание по ЛИФО или ФИФО, больше не указывать их.

Из этого последнего замечания вытекает ещё одна особенность проведения документов, на этот раз, касающаяся приходной накладной. Прежде чем её провести, нам нужно знать, должна ли она указываться в качестве партии или нет. А для этого прежде нужно прочитать текущее значение учетной политики.

Подведём итоги:

• Нам нужно создать документ, фиксирующий изменения учетной политики;
• При переходе на списание по средней этот документ должен сворачивать партии;
• Поэтому он будет регистратором не только в регистре сведений об учетной политике, но и в регистре накопления остатков номенклатуры;
• Соответственно в регистре сведений об учетной политике должна быть указана зависимость от регистратора;
• Кроме того, в этом регистре должна быть установлена периодичность в пределах дня;
• При списании по средней в движениях приходной накладной не следует указывать партию.

Вот в принципе и всё. Алгоритм проведения расходной накладной, и даже запрос, который он делает, не меняется. А о том, как запретить ввод документов задним числом мы расскажем в задаче 6.

Создаем регистр сведений МетодыСписанияСебестоимости, устанавливаем его Периодичность В пределах дня, Режим записи Подчинение регистратору. Добавим регистр в подсистему ОперативныйУчет, а на закладке «Данные» создадим ресурс Метод типа ПеречислениеСсылка.УчетнаяПолитика.

В этом преречислении уже имеются значения ЛИФО и ФИФО, нужно добавить ещё одно значение: ПоСредней.

Создаем документ ПриказОбУчетнойПолитике, добавляем его в подсистему ОперативныйУчет/Документы, на закладке «Данные» создаём реквизит МетодСписанияСебестоимости типа ПеречислениеСсылка.УчетнаяПолитика, а на закладке «Движения» укажем, что он является регистратором для регистров МетодыСписанияСебестоимости и ОстаткиНоменклатуры.

Переходим к описанию алгоритма проведения документа: прежде всего указываем, что все созданные нами движения нужно записывать, иначе весь наш труд пойдёт прахом.

Далее, сразу же стираем старую запись в регистре сведений, чтобы прочитать какой метод списания устанавливают другие документы. Если они устанавливают другой метод, то записываем свой. Если наш документ не изменяет метод списания, то в принципе можно ничего не делать.

Если наш документ изменяет прежний метод списания на метод списания ПоСредней, то приступаем к сворачиванию партий. Для этого прежде всего нужно прочитать все остатки по партиям на МоментВремени проведения документа. Прямо в запросе посчитаем суммарные остатки по каждой номенклатуре, чтобы не делать лишних движений.

Дальше, во вложенном цикле пускаем в расход остатки по партиям, во внешнем цикле приходуем суммарные остатки по номенклатуре без указания партии.

Процедура ОбработкаПроведения(Отказ, Режим)

    Движения.МетодыСписанияСебестоимости.Записывать = Истина;
    Движения.ОстаткиНоменклатуры.Записывать = Истина;

    Движения.МетодыСписанияСебестоимости.Записать();

    Если МетодСписанияСебестоимости
        <> РегистрыСведений.МетодыСписанияСебестоимости.ПолучитьПоследнее(Дата).Метод Тогда

        // регистр МетодыСписанияСебестоимости
        Движение = Движения.МетодыСписанияСебестоимости.Добавить();
        Движение.Период = Дата;
        Движение.Метод = МетодСписанияСебестоимости;

        Если МетодСписанияСебестоимости = Перечисления.УчетнаяПолитика.ПоСредней Тогда

            Запрос = Новый Запрос;
            Запрос.Текст =
                "ВЫБРАТЬ
                |   ОстаткиНоменклатурыОстатки.Номенклатура КАК Номенклатура,
                |   ОстаткиНоменклатурыОстатки.Партия,
                |   ОстаткиНоменклатурыОстатки.КоличествоОстаток КАК КоличествоОстаток,
                |   ОстаткиНоменклатурыОстатки.СтоимостьОстаток КАК СтоимостьОстаток
                |ИЗ
                |   РегистрНакопления.ОстаткиНоменклатуры.Остатки(&МоментВремени, )
                |       КАК ОстаткиНоменклатурыОстатки
                |
                |ИТОГИ
                |   СУММА(КоличествоОстаток),
                |   СУММА(СтоимостьОстаток)
                |ПО
                |   Номенклатура";

            Запрос.УстановитьПараметр("МоментВремени", МоментВремени());
            
            Движения.ОстаткиНоменклатуры.Записать();
            ВыборкаНоменклатура = Запрос.Выполнить().Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам);
            Пока ВыборкаНоменклатура.Следующий() Цикл
                ВыборкаДетальныеЗаписи = ВыборкаНоменклатура.Выбрать();
                Пока ВыборкаДетальныеЗаписи.Следующий() Цикл

                    // регистр ОстаткиНоменклатуры Расход
                    Движение = Движения.ОстаткиНоменклатуры.Добавить();
                    Движение.ВидДвижения = ВидДвиженияНакопления.Расход;
                    Движение.Период = Дата;
                    Движение.Номенклатура = ВыборкаДетальныеЗаписи.Номенклатура;
                    Движение.Партия = ВыборкаДетальныеЗаписи.Партия;
                    Движение.Количество = ВыборкаДетальныеЗаписи.КоличествоОстаток;
                    Движение.Стоимость = ВыборкаДетальныеЗаписи.СтоимостьОстаток;

                КонецЦикла;

                // регистр ОстаткиНоменклатуры Приход
                Движение = Движения.ОстаткиНоменклатуры.Добавить();
                Движение.ВидДвижения = ВидДвиженияНакопления.Приход;
                Движение.Период = Дата;
                Движение.Номенклатура = ВыборкаНоменклатура.Номенклатура;
                Движение.Количество = ВыборкаНоменклатура.КоличествоОстаток;
                Движение.Стоимость = ВыборкаНоменклатура.СтоимостьОстаток;

            КонецЦикла;
        КонецЕсли;
    КонецЕсли;

КонецПроцедуры

Теперь посмотрим какие дополнения нам нужно сделать в алгоритме проведения документа приходная накладная. Во-первых, в самое начало процедуры ОбработкаПроведения воткнём чтение и проверку наличия сведений о методе списания себестоимости.

Если таковых не имеется, отказываемся проводить документ и выходим из процедуры.

 Метод = РегистрыСведений.МетодыСписанияСебестоимости.ПолучитьПоследнее(МоментВремени()).Метод;

    Если Метод = Перечисления.УчетнаяПолитика.ПустаяСсылка() Тогда

        Сообщение = Новый СообщениеПользователю;
        Сообщение.Текст = "Документ не может быть преведён, поскольку не определён метод списания себестоимости!";
        Сообщение.Сообщить(); 

        Отказ = Истина;
        Возврат;
	
    КонецЕсли;

Теперь отыскиваем строку кода, в которой указывается партия и выполняем её только если метод списания не ПоСредней.

Если Не (Метод = Перечисления.УчетнаяПолитика.ПоСредней) Тогда
     Движение.Партия = Ссылка;
КонецЕсли;

Основное требование - списывать товар из указанной в табличной части партии, а в случае если его по выбранной партии не хватает (или нет), то необходимо организовать списание в соответствии с текущей учетной политикой. Реализация этого требования и будет основной сложностью данной задачи, потому что со всем остальным нам уже приходилось сталкиваться.

Кроме того, необходимо построить пару отчетов, которые по своей сложности ничуть не превосходят те, с которыми мы имели дело в задачах 1 - 3. Поэтому эти отчеты будут оставлены нами без внимания, а вместо них предлагаем детально обсудить нюансы, вытекающие из основного требования.

Суть проблемы заключается в так называемых «Дублях строк». Под этим термином обычно подразумевается, что пользователь дважды (или более) совершает одно и то же действие, например, списывает один и тот же товар. Возможно, он делает это по вполне объективным причинам. Например, одна часть товара продается по одной цене, а другая часть по другой цене. Но наличие повторов номенклатуры может существенно повлиять на логику программы.

Например, пользователь дважды списывает по три единицы товара - итого шесть, а на складе остатки по двум партиям: в одной пять единиц, в другой две – итого семь. Если в запросе мы будем подбирать остатки к каждой записи о списании товара, то, поскольку записей две, мы подберём одни и те же остатки дважды. И каждый раз будем преспокойненько списывать по три единицы с первой партии, думая, что у нас ещё даже остается две единицы в запасе. То есть из-за дубля строк у нас происходит неявное задвоение остатков в алгоритме: четырнадцать вместо семи.

Чтобы не допускать такой ошибки, от «Дублей строк», по мере возможности, сразу избавляются. В предыдущих задачах вы могли видеть, что мы всегда группируем записи расходной накладной по номенклатуре. Таким образом, в нашем примере, вместо двух записей по три единицы мы получаем одну запись на шесть единиц. И естественно к одной записи мы и остаток подбираем один раз, в нашем примере семь единиц. Теперь не будет ни какой ошибки. Сразу видно: "Шесть больше пяти - остатка не хватает", - нужно переходить к следующей партии.

В предыдущих задачах возможность сразу избавиться от «Дублей строк» у нас была, поскольку нигде в отчётах не требовалось знать какая часть товаров, по какой конкретно цене, была реализована: отчет Продажи составляется в целом по итогам указанного периода, а поскольку дубли строк встречаются в одном документе, они проводятся датой документа и попадают в один период.

В этой задаче ситуация существенно отличная: «Дубли строк» могут отличаться не только ценой, но и указанной в них партией. Если в разных строках для одной и той же номенклатуры указана одна и та же партия, мы можем их сгруппировать. Но если в разных строках для одной и той же номенклатуры указаны разные партии, в этих партиях может не хватить товара и нам придётся подбирать остатки из других партий. Следовательно, у нас снова произойдет неявное задвоение остатков в алгоритме.

В задаче 2 партия указывалась в шапке документа и, следовательно, была одной и той же для любой строки табличной части - там такого произойти не могло. В задаче 3 мы не подбирали остатки из других партий и, следовательно, остатки по другим партиям не могли задваиваться. Как же нам поступить здесь?

В принципе ответ очевиден: чтобы остатки не задваивались, мы должны подбирать их один лишь раз. А вот списывать с указанных партий мы должны персонально. То есть мы должны списать с указанных партий ровно столько, сколько указано и, если в них что-то останется, то тогда уже подбирать эти остатки для списания по методу указанному в учетной политике. Поскольку остатки подбираются один раз, нам нужно будет сгруппировать все записи по номенклатуре, потом со всех указанных партий списать (если хватает) указанное количество товара. Если в каких-то партиях товара не хватает, суммировать недостачу, и списывать её с других партий, в которых что-то ещё осталось.

То есть с каждой партии товар может списываться дважды: первый раз в количестве не больше указанного, второй раз в порядке очерёдности согласно Учётной политике в пределах того, чего не хватило в указанных партиях. Значит, мы должны все остатки по партиям разбить на две части: 1) в пределах указанного, 2) сверх указанного. Первые части запрос должен располагать впереди в любом порядке, вторые - следом в порядке определённом Учётной политикой.

Ну что ж, будем считать, что аналитические процедуры мы завершили успешно, переходим к реализации!

Итак, особенность задачи в том лишь и состоит, что нам нужно исхитриться в одном пакетном запросе подготовить данные для алгоритма так, чтобы не пришлось менять его логику, отточенную в предыдущих задачах. Давайте приступим:

В первом запросе пакета мы выберем данные из Расходной накладной, сгруппируем их по Номенклатуре и Партии, и поместим во временную таблицу РасходнаяНакладная. Во втором запросе пакета мы выберем данные из Расходной накладной, сгруппируем их по Номенклатуре, и поместим во временную таблицу РасходнаяНакладнаяБезПартий.

Поскольку нам придётся много работать с остатками, в третьем запросе пакета мы выберем их и поместим во временную таблицу ОстаткиНоменклатуры. Как водится, чтобы не читать лишнего и не перегружать компьютер бесполезной информацией, выбираем остатки только по той Номенклатуре, которая упоминается в Расходной накладной. И не забываем указать на какой момент времени нас интересуют остатки.

Далее, определяем, сколько можно списать по указанной партии: Если остаток по партии больше чем требуется, списываем, сколько нужно, а нет, так списываем, сколько есть. Помещаем эту информацию во временную таблицу ДоступноДляСписания, с ней нам ещё придётся поработать.

Потом мы объединяем данные запроса о том, сколько мы можем списать по партиям указанным в документе, с тем, что после этого останется. И тут же определяем Порядок сортировки. Для доступных для списания данных используем 0, они будут первыми. А для сортировки того, что остается, используем 1. Помещаем результат объединения во временную таблицу ПартииДляСписания.

В последнем запросе мы соединяем данные расходной накладной, с подготовленными данными об остатках. Сортируем по ранее определённому полю Порядку, потом по моменту времени Партии в порядке, определяемом учетной политикой. Создаем итоги по Номенклатуре. Всё, пакет запросов готов!

И вот, что у нас должно было получиться:

Запрос = Новый Запрос;
Запрос.Текст ="ВЫБРАТЬ
|	РасходнаяНакладнаяСписокНоменклатуры.Номенклатура КАК Номенклатура,
|	РасходнаяНакладнаяСписокНоменклатуры.Партия,
|	СУММА(РасходнаяНакладнаяСписокНоменклатуры.Количество) КАК Количество,
|	СУММА(РасходнаяНакладнаяСписокНоменклатуры.Сумма) КАК Сумма
|ПОМЕСТИТЬ РасходнаяНакладная
|ИЗ
|	Документ.РасходнаяНакладная.СписокНоменклатуры КАК РасходнаяНакладнаяСписокНоменклатуры
|ГДЕ
|	РасходнаяНакладнаяСписокНоменклатуры.Ссылка = &Ссылка
|
|СГРУППИРОВАТЬ ПО
|	РасходнаяНакладнаяСписокНоменклатуры.Номенклатура,
|	РасходнаяНакладнаяСписокНоменклатуры.Партия
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
|	РасходнаяНакладная.Номенклатура,
|	СУММА(РасходнаяНакладная.Количество) КАК Количество,
|	СУММА(РасходнаяНакладная.Сумма) КАК Сумма
|ПОМЕСТИТЬ РасходнаяНакладнаяБезПартий
|ИЗ
|	РасходнаяНакладная КАК РасходнаяНакладная
|
|СГРУППИРОВАТЬ ПО
|	РасходнаяНакладная.Номенклатура
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
|	ОстаткиНоменклатурыОстатки.Номенклатура,
|	ОстаткиНоменклатурыОстатки.Партия,
|	ОстаткиНоменклатурыОстатки.КоличествоОстаток,
|	ОстаткиНоменклатурыОстатки.СтоимостьОстаток
|ПОМЕСТИТЬ ОстаткиНоменклатуры
|ИЗ
|	РегистрНакопления.ОстаткиНоменклатуры.Остатки(
|			&МоментВремени,
|			Номенклатура В
|				(ВЫБРАТЬ
|					РасходнаяНакладнаяБезПартий.Номенклатура
|				ИЗ
|					РасходнаяНакладнаяБезПартий)) КАК ОстаткиНоменклатурыОстатки
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
|	РасходнаяНакладная.Номенклатура,
|	РасходнаяНакладная.Партия,
|	ВЫБОР
|		КОГДА РасходнаяНакладная.Количество > ОстаткаНоменклатуры.КоличествоОстаток
|			ТОГДА ОстаткаНоменклатуры.КоличествоОстаток
|		ИНАЧЕ РасходнаяНакладная.Количество
|	КОНЕЦ КАК ДоступноКоличество,
|	ВЫБОР
|		КОГДА РасходнаяНакладная.Количество > ОстаткаНоменклатуры.КоличествоОстаток
|			ТОГДА ОстаткаНоменклатуры.СтоимостьОстаток
|		ИНАЧЕ РасходнаяНакладная.Количество * ОстаткаНоменклатуры.СтоимостьОстаток / 
|                                                           ОстаткаНоменклатуры.КоличествоОстаток
|	КОНЕЦ КАК ДоступноСтоимость
|ПОМЕСТИТЬ ДоступноДляСписания
|ИЗ
|	РасходнаяНакладная КАК РасходнаяНакладная
|		ВНУТРЕННЕЕ СОЕДИНЕНИЕ ОстаткиНоменклатуры КАК ОстаткаНоменклатуры
|		ПО РасходнаяНакладная.Номенклатура = ОстаткаНоменклатуры.Номенклатура
|			И РасходнаяНакладная.Партия = ОстаткаНоменклатуры.Партия
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
|	0 КАК Порядок,
|	ДоступноДляСписания.Номенклатура,
|	ДоступноДляСписания.Партия,
|	ДоступноДляСписания.ДоступноКоличество КАК КоличествоОстаток,
|	ДоступноДляСписания.ДоступноСтоимость КАК СтоимостьОстаток
|ПОМЕСТИТЬ ПартииДляСписания
|ИЗ
|	ДоступноДляСписания КАК ДоступноДляСписания
|
|ОБЪЕДИНИТЬ ВСЕ
|
|ВЫБРАТЬ
|	1,
|	ОстаткаНоменклатуры.Номенклатура,
|	ОстаткаНоменклатуры.Партия,
|	ОстаткаНоменклатуры.КоличествоОстаток - ЕСТЬNULL(ДоступноДляСписания.ДоступноКоличество, 0),
|	ОстаткаНоменклатуры.СтоимостьОстаток - ЕСТЬNULL(ДоступноДляСписания.ДоступноСтоимость, 0)
|ИЗ
|	ОстаткиНоменклатуры КАК ОстаткаНоменклатуры
|		ЛЕВОЕ СОЕДИНЕНИЕ ДоступноДляСписания КАК ДоступноДляСписания
|		ПО (ДоступноДляСписания.Номенклатура = ОстаткаНоменклатуры.Номенклатура)
|			И (ДоступноДляСписания.Партия = ОстаткаНоменклатуры.Партия)
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
|	РасходнаяНакладнаяБезПартий.Номенклатура КАК Номенклатура,
|	РасходнаяНакладнаяБезПартий.Количество КАК Количество,
|	РасходнаяНакладнаяБезПартий.Сумма КАК Сумма,
|	ПартииДляСписания.Порядок КАК Порядок,
|	ПартииДляСписания.Партия,
|	ЕСТЬNULL(ПартииДляСписания.КоличествоОстаток, 0) КАК КоличествоОстаток,
|	ЕСТЬNULL(ПартииДляСписания.СтоимостьОстаток, 0) КАК СтоимостьОстаток
|ИЗ
|	РасходнаяНакладнаяБезПартий КАК РасходнаяНакладнаяБезПартий
|		ЛЕВОЕ СОЕДИНЕНИЕ ПартииДляСписания КАК ПартииДляСписания
|		ПО РасходнаяНакладнаяБезПартий.Номенклатура = ПартииДляСписания.Номенклатура
|ГДЕ
|	ПартииДляСписания.КоличествоОстаток > 0
|
|УПОРЯДОЧИТЬ ПО
|	Порядок,
|	ПартииДляСписания.Партия.МоментВремени "+?(МетодСписания=Перечисления.УчетнаяПолитика.ФИФО, "ВОЗР", "УБЫВ")+"
|ИТОГИ
|	МАКСИМУМ(Количество),
|	МАКСИМУМ(Сумма),
|	СУММА(КоличествоОстаток)
|ПО
|	Номенклатура";

Алгоритм проведения можем взять хотя бы из задачи 1 Только нужно будет устранить из него всё, что касается услуг.

Необходимо построить отчет по анализу продаж товаров за период и остаткам товара на указанную дату. Ориентировочный вид обоих отчетов приведен ниже:

Где:
Интервал = «Дата первой отгрузки» - «Дата последней отгрузки» / «Количество отгрузок» (или "разовая", если «Количество отгрузок» = 1)
Срок = «Конец периода отчета» - «Дата последней отгрузки»

Очевидно, что мы имеем дело еще с одной небольшой вариацией задачи 1, решение которой возьмем за основу. Т.к. учетная политика здесь отсутствует как таковая, то первым делом выкинем из конфигурации одноименный регистр сведений. А также уберем из обработки проведения документа РасходнаяНакладная обращение к этому регистру и сортировку партий в запросе.

В задаче требуется списывать не все доступные партии, а только те, что указаны в табличной части документа РасходнаяНакладная, поэтому добавим в его табличную часть СписокНоменклатуры новый реквизит Партия типа ДокументСсылка.ПриходнаяНакладная. Т.к. по условию задачи услуги и товары указываются в одной табличной части, то свойство Проверка заполнения нового реквизита оставим имеющим значение Не проверять. Подправим текст запроса таким образом, чтобы он возвращал остатки сразу для пары {номенклатура, партия} (новые строки выделены 4мя вертикальными полосками ||||):

    // Чтение партий, доступных для списания.
    Запрос = Новый Запрос;
    Запрос.Текст =
        "ВЫБРАТЬ
        |   РасходнаяНакладнаяСписокНоменклатуры.Номенклатура,
        |   РасходнаяНакладнаяСписокНоменклатуры.Номенклатура.ВидНоменклатуры КАК ВидНоменклатуры,
        ||||   РасходнаяНакладнаяСписокНоменклатуры.Партия,
        |   СУММА(РасходнаяНакладнаяСписокНоменклатуры.Количество) КАК Количество,
        |   СУММА(РасходнаяНакладнаяСписокНоменклатуры.Сумма) КАК Сумма
        |ПОМЕСТИТЬ РасходнаяНакладная
        |ИЗ
        |   Документ.РасходнаяНакладная.СписокНоменклатуры КАК РасходнаяНакладнаяСписокНоменклатуры
        |ГДЕ
        |   РасходнаяНакладнаяСписокНоменклатуры.Ссылка = &Ссылка
        |
        |СГРУППИРОВАТЬ ПО
        |   РасходнаяНакладнаяСписокНоменклатуры.Номенклатура,
        |   РасходнаяНакладнаяСписокНоменклатуры.Номенклатура.Услуга,
        ||||   РасходнаяНакладнаяСписокНоменклатуры.Партия
        |;
        |
        |////////////////////////////////////////////////////////////////////////////////
        |ВЫБРАТЬ
        |   РасходнаяНакладная.Номенклатура КАК Номенклатура,
        |   ВЫБОР КОГДА РасходнаяНакладная.ВидНоменклатуры = Значение(Перечисление.ВидНоменклатуры.Услуга) ТОГДА Истина ИНАЧЕ Ложь КОНЕЦ КАК ЭтоУслуга,
        ||||   РасходнаяНакладная.Партия КАК Партия,
        |   РасходнаяНакладная.Количество КАК Количество,
        |   РасходнаяНакладная.Сумма,
        |   ЕСТЬNULL(ОстаткиНоменклатурыОстатки.КоличествоОстаток, 0) КАК КоличествоОстаток,
        |   ЕСТЬNULL(ОстаткиНоменклатурыОстатки.СтоимостьОстаток, 0) КАК СтоимостьОстаток
        |ИЗ
        |   РасходнаяНакладная КАК РасходнаяНакладная
        |       ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.ОстаткиНоменклатуры.Остатки(
        |               &МоментВремени,
        ||||               (Номенклатура, Партия) В
        ||||                   (ВЫБРАТЬ
        ||||                       РасходнаяНакладная.Номенклатура,
        ||||                       РасходнаяНакладная.Партия
        ||||                   ИЗ
        ||||                       РасходнаяНакладная)) КАК ОстаткиНоменклатурыОстатки
        ||||       ПО РасходнаяНакладная.Номенклатура = ОстаткиНоменклатурыОстатки.Номенклатура
        ||||           И РасходнаяНакладная.Партия = ОстаткиНоменклатурыОстатки.Партия
        ||||ИТОГИ
        ||||	МИНИМУМ(ЭтоУслуга),
        ||||	МИНИМУМ(Количество),
        ||||	МИНИМУМ(Сумма)
        ||||ПО
        ||||	Номенклатура";

    Запрос.УстановитьПараметр("Ссылка", Ссылка);
    Запрос.УстановитьПараметр("МоментВремени", МоментВремени());

Заметим, что в запросе отсутствует упорядочивание. Дело в том, что для каждой пары {номенклатура, партия} из табличной части мы выбираем из регистра не список партий (как в задачах 1 или 2), а только одну партию.

Однако мы продолжаем формировать итоги по номенклатуре, потому что ни что не мешает пользователю задать в табличной части отгрузку одного и того же товара из разных партий. Тогда как в регистре Продажи партии не указываются, а списывается суммарная стоимость и количество по всем партиям.

Но при этом мы, конечно же, не подсчитываем суммарный остаток по всем партиям, указанным для данной номенклатуры, поскольку необходимо контролировать наличие остатков достаточных для отгрузки, по каждой партии в отдельности.

Одним из важнейших аспектов программирования является правильная блокировка данных. Здесь мы продемонстрируем использование управляемой блокировки. В регистре накопления ОстаткиНоменклатуры блокируются все указанные в табличной части документа СписокНоменклатуры сочетания номенклатуры и партии. То есть другой документ сможет списывать другую номенклатуру с той же партии и ту же номенклатуру с другой партии. Таким образом, мы блокируем только то, что нам понадобится, И позволяем другим документам беспрепятственно работать со всем остальным.

Перед тем как выполнить чтение данных из регистра ОстаткиНоменклатуры, мы стираем прежние движения этого документа, если они были, записывая пустой набор движений. Но ещё прежде мы указываем, что все остатки и обороты, на которые влияли наши прежние движения, следует БлокироватьДляИзменения. Это на тот случай, если по итогам проверки остатков в партиях, мы решимся отказаться от записи новых движений и вернуть прежние. Ведь пока мы производим проверки и формируем движения, другой документ может забрать то, что временно освободилось, когда мы стерли прежние движения.

    Блокировка = Новый БлокировкаДанных;
    ЭлементБлокировки = Блокировка.Добавить("РегистрНакопления.ОстаткиНоменклатуры");
    ЭлементБлокировки.Режим = РежимБлокировкиДанных.Исключительный;
    ЭлементБлокировки.ИсточникДанных = СписокНоменклатуры;
    ЭлементБлокировки.ИспользоватьИзИсточникаДанных("Номенклатура", "Номенклатура");
    ЭлементБлокировки.ИспользоватьИзИсточникаДанных("Партия", "Партия");
    Блокировка.Заблокировать();
   
    Движения.ОстаткиНоменлатуры.Записывать = Истина;
    Движения.ОстаткиНоменклатуры.Записать();

Ну, вот теперь мы можем смело читать остатки и приступать к формированию движений. В принципе это делается также, как и в задаче 1, только проверка наличия остатков погружается в цикл обхода детальных записей, не требуется контролировать сколько осталось списать, а сам этот цикл выполняется только когда номенклатура не является услугой.

    Результат = Запрос.Выполнить();
    ВыборкаНоменклатура = Результат.Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам);

    Пока ВыборкаНоменклатура.Следующий() Цикл

        ТекСебестоимость = 0;

        Если НЕ ВыборкаНоменклатура.ЭтоУслуга Тогда 

        ВыборкаДетальныеЗаписи = ВыборкаНоменклатура.Выбрать();

            Пока ВыборкаДетальныеЗаписи.Следующий() Цикл

                // Контроль остатков
                Если ВыборкаНоменклатура.Количество > ВыборкаНоменклатура.КоличествоОстаток Тогда
              
                    Сообщение = Новый СообщениеПользователю;
                    Сообщение.Текст = "В партии " + ВыборкаДетальныеЗаписи.Партия
                                    + " не хватает """ + ВыборкаДетальныеЗаписи.Номенклатура
                                    + """. Требуется: " + ВыборкаДетальныеЗаписи.Количество
                                    + ", остаток: " + ВыборкаДетальныеЗаписи.КоличествоОстаток + ".";
                    Сообщение.Сообщить();

                    Отказ = Истина;
                КонецЕсли;

                Если Отказ Тогда
                    Продолжить;
                КонецЕсли;

                // регистр ОстаткиНоменклатуры Расход
                Движение = Движения.ОстаткиНоменклатуры.Добавить();
                Движение.ВидДвижения = ВидДвиженияНакопления.Расход;
                Движение.Период = Дата;
                Движение.Номенклатура = ВыборкаДетальныеЗаписи.Номенклатура;
                Движение.Партия = ВыборкаДетальныеЗаписи.Партия;
                Движение.Количество = ВыборкаДетальныеЗаписи.Количество;
                Движение.Стоимость = (ВыборкаДетальныеЗаписи.Количество * ВыборкаДетальныеЗаписи.СтоимостьОстаток) /
                                                            ВыборкаДетальныеЗаписи.КоличествоОстаток;

                ТекСебестоимость = ТекСебестоимость + Движение.Стоимость;
            КонецЦикла;
        КонецЕсли;
        
        // регистр Продажи
        Движение = Движения.Продажи.Добавить();
        Движение.Период = Дата;
        Движение.Номенклатура = ВыборкаНоменклатура.Номенклатура;
        Движение.Количество = ВыборкаНоменклатура.Количество;
        Движение.Себестоимость = ТекСебестоимость;
        Движение.Выручка = ВыборкаНоменклатура.Сумма;
        КонецЦикла;

Отчет «Остатки товаров» полностью совпадает с одноименным отчетом задачи 1, поэтому его реализация рассматриваться здесь не будет. Создадим новый отчет АнализПродаж, добавим его в подсистему Оперативный учет, а затем на вкладке «Основные» нажмем кнопку «Открыть схему компоновки данных». В схему добавим набор данных вида «Запрос». Укажем следующий текст запроса:

ВЫБРАТЬ
    ПродажиОбороты.Номенклатура,
    МИНИМУМ(ПродажиОбороты.Период) КАК Минимум,
    МАКСИМУМ(ПродажиОбороты.Период) КАК Максимум,
    КОЛИЧЕСТВО(РАЗЛИЧНЫЕ ПродажиОбороты.Регистратор) КАК N,
    СУММА(ПродажиОбороты.КоличествоОборот) КАК Количество,
    СУММА(ПродажиОбороты.ВыручкаОборот) КАК Продажа,
    СУММА(ПродажиОбороты.СебестоимостьОборот) КАК Себестоимость
ИЗ
    РегистрНакопления.Продажи.Обороты(, , Регистратор, ) КАК ПродажиОбороты

СГРУППИРОВАТЬ ПО
    ПродажиОбороты.Номенклатура

Запрос вернет основные данные для нашего отчета, но часть необходимой нам информации - поля Прибыль/Интервал/Срок - среди них отсутствуют. Ничто не мешает усложнить запрос таким образом, чтобы он возвращал все, что нам нужно. Но мы предпочитаем действовать иначе, а именно - собираемся вычислять значения этих полей в самой схеме компоновки данных. Для этого перейдем на вкладку «Вычисляемые поля» и внесем на ней ряд изменении:

Перейдем на закладку «Параметры». Установим параметры отчета согласно рисунка.

Перейдем на закладку «Настройки». Добавим в структуру нашего отчета новую группировку (клавиша Ins), но поле группировки указывать не будем (клавиша Enter). На вкладке «Выбранные поля» укажем список полей отчета, согласно требуемой формы.

Рядом с вкладкой «Выбранные поля» расположена вкладка «Параметры». Перейдем на нее и выполним настройку параметра «Период» отчета.

Последний штрих - переходим на вкладку «Другие настройки» и задаем заголовок отчета.

Очевидно, что мы имеем дело с ситуацией, когда небольшая вариация условия задачи приводит к аналогичным по масштабу изменениям в решении. Решение задачи 1 нами было подробно описано в соответствующем разделе, возьмем его за основу. Рассмотрим изменения, которые необходимо дополнительно в него внести.

Во-первых, в документ РасходнаяНакладная нам потребуется добавить реквизит Партия типа ДокументСсылка.ПриходнаяНакладная. Т.к. в условии задачи ничто не говорит о том, что этот реквизит может не заполняться, то установим его свойство Проверка заполнения в значение Выдавать ошибку.

Второе (и последнее) изменение, которое нам предстоит сделать - это подправить немного текст запроса в обработке проведения документа РасходнаяНакладная. Напомним, что сейчас запрос получает список партий, доступных для списания, а также сортирует его согласно текущей учетной политики (ФИФО - по возрастанию дат партий, ЛИФО - по убыванию дат партий).

В это список может попасть и наша партия - та, что указана в шапке документа РасходнаяНакладная. Только при любом методе сортировки нам нужно, чтобы она оказалась на первом месте (если по ней есть что списывать, естественно). Тогда бы, мы первым делом списали товар именно из этой партии, а потом бы перешли к прочим, уже отсортированным как надо. Реализуем это так (новые строки выделены 4мя вертикальными линиями ||||):

   // Чтение партий, доступных для списания. 
   //Сортировка согласно требованию
    Запрос = Новый Запрос;
    Запрос.Текст =
        "ВЫБРАТЬ
        |   РасходнаяНакладнаяСписокНоменклатуры.Номенклатура,
        |   РасходнаяНакладнаяСписокНоменклатуры.Номенклатура.ВидНоменклатуры КАК ВидНоменклатуры,
        |   СУММА(РасходнаяНакладнаяСписокНоменклатуры.Количество) КАК Количество,
        |   СУММА(РасходнаяНакладнаяСписокНоменклатуры.Сумма) КАК Сумма
        |ПОМЕСТИТЬ РасходнаяНакладная
        |ИЗ
        |   Документ.РасходнаяНакладная.СписокНоменклатуры КАК РасходнаяНакладнаяСписокНоменклатуры
        |ГДЕ
        |   РасходнаяНакладнаяСписокНоменклатуры.Ссылка = &Ссылка
        |
        |СГРУППИРОВАТЬ ПО
        |   РасходнаяНакладнаяСписокНоменклатуры.Номенклатура,
        |   РасходнаяНакладнаяСписокНоменклатуры.Номенклатура.Услуга
        |;
        |
        |////////////////////////////////////////////////////////////////////////////////
        |ВЫБРАТЬ
        |   РасходнаяНакладная.Номенклатура КАК Номенклатура,
        |   ВЫБОР КОГДА РасходнаяНакладная.ВидНоменклатуры = Значение(Перечисление.ВидНоменклатуры.Услуга) ТОГДА Истина ИНАЧЕ Ложь КОНЕЦ КАК ЭтоУслуга,
        |   РасходнаяНакладная.Количество КАК Количество,
        |   РасходнаяНакладная.Сумма,
        |   ОстаткиНоменклатурыОстатки.Партия КАК Партия,
        ||||   ВЫБОР
        ||||       КОГДА ОстаткиНоменклатурыОстатки.Партия = &Партия
        ||||           ТОГДА 0
        ||||       ИНАЧЕ 1
        ||||   КОНЕЦ КАК Порядок,
        |   ЕСТЬNULL(ОстаткиНоменклатурыОстатки.КоличествоОстаток, 0) КАК КоличествоОстаток,
        |   ЕСТЬNULL(ОстаткиНоменклатурыОстатки.СтоимостьОстаток, 0) КАК СтоимостьОстаток
        |ИЗ
        |   РасходнаяНакладная КАК РасходнаяНакладная
        |       ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.ОстаткиНоменклатуры.Остатки(
        |               &МоментВремени,
        |               Номенклатура В
        |                   (ВЫБРАТЬ
        |                       РасходнаяНакладная.Номенклатура
        |                   ИЗ
        |                       РасходнаяНакладная)) КАК ОстаткиНоменклатурыОстатки
        |       ПО РасходнаяНакладная.Номенклатура = ОстаткиНоменклатурыОстатки.Номенклатура
        |
        |УПОРЯДОЧИТЬ ПО
        ||||   Порядок,
        |   ОстаткиНоменклатурыОстатки.Партия.МоментВремени" + СортировкаПартий + "
        |ИТОГИ
        |   МАКСИМУМ(Услуга),
        |   МАКСИМУМ(Количество),
        |   МАКСИМУМ(Сумма),
        |   СУММА(КоличествоОстаток)
        |ПО
        |   Номенклатура";        
    Запрос.УстановитьПараметр("Ссылка", Ссылка);
    Запрос.УстановитьПараметр("МоментВремени", МоментВремени());
    ||||Запрос.УстановитьПараметр("Партия", Партия);

Складной учет не ведется.

При проведении расходной накладной при нехватке товара необходимо выдавать соответствующее предупреждение с указанием количества нехватки и не позволять проводить документ.

Списание себестоимости должно быть организованно по партиям, в Зависимости от значения, принятого на этот год в учетной политике Метода списания себестоимости (FIFO или LIFO). Еще раз подчеркивается – Учетная политика действует год. На следующий год метод списания может смениться.

Необходимо построить отчет по продажам товаров за период и остаткам товаров на указанную дату. Ориентировочный вид обоих отчетов приведен ниже:

Переводим режим управления блокировкой данных каркасной конфигурации в значение Управляемый. Находим в дереве конфигурации элемент Общие | Подсистемы, создаем подчиненную подсистему ОперативныйУчет с одноименной картинкой, а затем две вложенные в нее подсистемы Документы и Справочники. Для последних задавать картинки не будем. Включим справочники Номенклатура и Контрагенты в подсистему Справочники, а документы ПриходнаяНакладная и РасходнаяНакладная в подсистему Документы.

В справочнике Номенклатура создаем новый реквизит ВидНоменклатуры типа ПеречислениеСсылка.ВидыНоменклатуры. Номенклатуре используемой в примере необходимо проставить вид ВидыНоменклатуры.Товар.

Для хранения текущего значения принятого на этот год в учетной политике метода списания себестоимости создадим регистр сведений УчетнаяПолитика. Периодичность - В пределах года, т.к. в задаче не сказано, что изменение учетной политики должно фиксироваться соответствующим документом, то оставляем Режим записи регистра без изменения (Независимый). Добавим регистр в подсистему ОперативныйУчет, а на закладке «Данные» создадим ресурс МетодСписания типа ПеречислениеСсылка.УчетнаяПолитика.

Сохраним изменения в конфигурации, проигнорировав список предупреждений вида «Объект не включен ни в одну подсистему, отображаемую в командном интерфейсе». В режиме 1С:Предприятия добавим в справочник Номенклатура новую группу Услуги, а в нее элемент - Доставка. Для номенклатуры Доставка укажем вид номенклатуры - Услуга. Далее, перейдем по ссылке Учетная политика, создадим в списке новый элемент, в котором укажем метод списания себестоимости Фифо.

Вернемся в режим Конфигуратора. Посмотрим внимательно на форму первого отчета и зададим себе вопрос о том, откуда будут браться данные для его формирования. Т.к. продажи - это по своей сути оборотная информация, то решим, что данные будут браться из соответствующего оборотного регистра накопления (назовем его Продажи), причем форма отчета диктует нам структуру этого регистра.

Аналогично, посмотрим внимательно на форму второго отчета и зададим себе вопрос о том, откуда будут браться данные для его формирования. Решим, что данные будут браться из соответствующего регистра накопления вида Остатки (назовем его ОстаткиНоменклатуры). В каркасной конфигурации уже присутствует регистр с таким именем, поэтому внесем требуемые изменения прямо в него.

В регистре ОстаткиНоменклатуры измерение Партия будет иметь тип ДокументСсылка.ПриходнаяНакладная. Другими словами, мы собираемся хранить остатки номенклатуры в разрезе конкретных документов ПриходнаяНакладная, по которым эта номенклатура к нам поступала. Например, на основе данных второго отчета можно сделать вывод, что приход номенклатуры «Big (капилярная)» происходил по документам «Приходная накладная 000000001» и «Приходная накладная 000000002», по каждому из них мы собираемся хранить текущий остаток номенклатуры и стоимость. Это и есть партионный учет, требуемый в задаче!

Перейдем к реализации логики проведения документов ПриходнаяНакладная и РасходнаяНакладная. Начнем с первого, для этого откроем модуль объекта документа ПриходнаяНакладная и добавим в него следующий код:

Процедура ОбработкаПроведения(Отказ, Режим)
    Движения.ОстаткиНоменклатуры.Записывать = Истина;

    // Получаем данные по Товарам документа и одновременно избавляемся
    // от дублей строк
    Запрос = Новый Запрос;
    Запрос.Текст =
    "ВЫБРАТЬ
    |   ПриходнаяНакладнаяСписокНоменклатуры.Номенклатура,
    |   СУММА(ПриходнаяНакладнаяСписокНоменклатуры.Количество) КАК Количество,
    |   СУММА(ПриходнаяНакладнаяСписокНоменклатуры.Сумма) КАК Сумма
    |ИЗ
    |   Документ.ПриходнаяНакладная.СписокНоменклатуры КАК ПриходнаяНакладнаяСписокНоменклатуры
    |ГДЕ
    |   ПриходнаяНакладнаяСписокНоменклатуры.Ссылка = &Ссылка
    |   И (НЕ ПриходнаяНакладнаяСписокНоменклатуры.Номенклатура.Услуга)
    |
    |СГРУППИРОВАТЬ ПО
    |   ПриходнаяНакладнаяСписокНоменклатуры.Номенклатура";

    Запрос.УстановитьПараметр("Ссылка", Ссылка);

    Результат = Запрос.Выполнить();

    ВыборкаДетальныеЗаписи = Результат.Выбрать();

    Пока ВыборкаДетальныеЗаписи.Следующий() Цикл

        // регистр ОстаткиНоменклатуры Приход
        Движение = Движения.ОстаткиНоменклатуры.Добавить();
        Движение.ВидДвижения = ВидДвиженияНакопления.Приход;
        Движение.Период = Дата;
        Движение.Партия = Ссылка;
        Движение.Номенклатура = ВыборкаДетальныеЗаписи.Номенклатура;
        Движение.Количество = ВыборкаДетальныеЗаписи.Количество;
        Движение.Стоимость = ВыборкаДетальныеЗаписи.Сумма;
    КонецЦикла;
КонецПроцедуры

Можно заметить, что логика проведения довольно прямолинейна, поэтому не требует дополнительных пояснений. Проведение документа РасходнаяНакладная немногим сложнее, но прежде чем переходить к нему, разберемся, как именно оно должно выглядеть, согласно требованиям задачи.

РасходнаяНакладная должна уменьшать остатки номенклатуры в регистре ОстаткиНоменклатуры, а также создавать движения в регистре Продажи. Причем, остатки номенклатуры у нас хранятся в разрезе партий (документов ПриходнаяНакладная), поэтому перед списанием номенклатуры необходимо будет получить из регистра список партий, доступных для списания. В соответствии с установленным значением на этот год в учетной политике методом списания себестоимости, будем сортировать этот список партий или по возрастанию дат документов (ФИФО - первый пришел, первый ушел), или по убыванию дат документов (ЛИФО - последний пришел, первый ушел).

Кроме того, при проведении документа РасходнаяНакладная требуется отслеживать нехватку товара. Для того чтобы понять хватает ли товара для проведения документа, неэффективно бегать по его списку партий. Лучшим решением будет озаботиться тем, чтобы у нас всегда были бы под рукой данные об общем количестве доступных единиц товара.

Наконец, для исключения коллизий, связанных с параллельной работой других пользователей, реализуем блокировку необходимых данных. Дело в том, что возможна такая ситуация, когда разные транзакции одновременно читают доступное количество некоего товара, а потом каждая транзакция списывает его. В результате чего контроль остатков будет работать неверно, а наша обязанность этого избежать. Поэтому, прежде чем читать что-то, что мы собираемся изменять, будем запрещать чтение этих данных другими транзакциями до тех пор, пока мы не закончим свои изменения (или пока не откажемся от проведения документа).

Процедура ОбработкаПроведения(Отказ, Режим)

    // Чтение метода списания себестоимости
    МетодСписания = РегистрыСведений.УчетнаяПолитика.
    ПолучитьПоследнее(Дата).МетодСписания;

    Если МетодСписания.Пустая() Тогда
        Сообщение = Новый СообщениеПользователю;
        Сообщение.Текст = "Учетная политика не определена!";
        Сообщение.Сообщить();

        Отказ = Истина;
        Возврат;
    КонецЕсли;

  СортировкаПартий = ?(МетодСписания = Перечисления.УчетнаяПолитика.ФИФО, 
  "", " УБЫВ");
    
    Движения.Продажи.Записывать = Истина;
    Движения.ОстаткиНоменклатуры.Записывать = Истина;
    Движения.ОстаткиНоменклатуры.Записать();
    // Блокировка данных
    Блокировка = Новый БлокировкаДанных;
    ЭлементБлокировки = Блокировка.Добавить("РегистрНакопления.
    ОстаткиНоменклатуры");
    ЭлементБлокировки.Режим = РежимБлокировкиДанных.Исключительный;
    ЭлементБлокировки.ИсточникДанных = СписокНоменклатуры;
    ЭлементБлокировки.ИспользоватьИзИсточникаДанных("Номенклатура", 
    "Номенклатура");

    Блокировка.Заблокировать();

    // Чтение партий, доступных для списания. Сортировка согласно метода 
    списания себестоимости
    Запрос = Новый Запрос;
    Запрос.Текст =
    "ВЫБРАТЬ
    |   РасходнаяНакладнаяСписокНоменклатуры.Номенклатура,
    |   РасходнаяНакладнаяСписокНоменклатуры.Номенклатура.ВидНоменклатуры КАК 
    ВидНоменклатуры,
    |   СУММА(РасходнаяНакладнаяСписокНоменклатуры.Количество) КАК Количество,
    |   СУММА(РасходнаяНакладнаяСписокНоменклатуры.Сумма) КАК Сумма
    |ПОМЕСТИТЬ РасходнаяНакладная
    |ИЗ
    |   Документ.РасходнаяНакладная.СписокНоменклатуры КАК 
    РасходнаяНакладнаяСписокНоменклатуры
    |ГДЕ
    |   РасходнаяНакладнаяСписокНоменклатуры.Ссылка = &Ссылка
    |
    |СГРУППИРОВАТЬ ПО
    |   РасходнаяНакладнаяСписокНоменклатуры.Номенклатура,
    |   РасходнаяНакладнаяСписокНоменклатуры.Номенклатура.ВидНоменклатуры
    |;
    |
    |////////////////////////////////////////////////////////////////////////////////
    |ВЫБРАТЬ
    |   РасходнаяНакладная.Номенклатура КАК Номенклатура,
    |   ВЫБОР КОГДА РасходнаяНакладная.ВидНоменклатуры = 
    Значение(Перечисление.ВидНоменклатуры.Услуга) ТОГДА Истина ИНАЧЕ 
    Ложь КОНЕЦ КАК ЭтоУслуга,
    |   РасходнаяНакладная.Количество КАК Количество,
    |   РасходнаяНакладная.Сумма,
    |   ОстаткиНоменклатурыОстатки.Партия КАК Партия,
    |   ЕСТЬNULL(ОстаткиНоменклатурыОстатки.КоличествоОстаток, 0) 
    КАК КоличествоОстаток,
    |   ЕСТЬNULL(ОстаткиНоменклатурыОстатки.СтоимостьОстаток, 0) КАК СтоимостьОстаток
    |ИЗ
    |   РасходнаяНакладная КАК РасходнаяНакладная
    |       ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.ОстаткиНоменклатуры.Остатки(
    |               &МоментВремени,
    |               Номенклатура В
    |                   (ВЫБРАТЬ
    |                       РасходнаяНакладная.Номенклатура
    |                   ИЗ
    |                       РасходнаяНакладная)) КАК ОстаткиНоменклатурыОстатки
    |       ПО РасходнаяНакладная.Номенклатура = ОстаткиНоменклатурыОстатки.Номенклатура
    |
    |УПОРЯДОЧИТЬ ПО
    |   ОстаткиНоменклатурыОстатки.Партия.МоментВремени" + СортировкаПартий + "
    |ИТОГИ
    |   МАКСИМУМ(Услуга),
    |   МАКСИМУМ(Количество),
    |   МАКСИМУМ(Сумма),
    |   СУММА(КоличествоОстаток)
    |ПО
    |   Номенклатура";

    Запрос.УстановитьПараметр("Ссылка", Ссылка);
    Запрос.УстановитьПараметр("МоментВремени", МоментВремени());

    Результат = Запрос.Выполнить();
    ВыборкаНоменклатура = 
    Результат.Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам);

    Пока ВыборкаНоменклатура.Следующий() Цикл

        // Контроль остатков
        Если (НЕ ВыборкаНоменклатура.Услуга) 
              И (ВыборкаНоменклатура.Количество > 
              ВыборкаНоменклатура.КоличествоОстаток) Тогда
              
            Сообщение = Новый СообщениеПользователю;
            Сообщение.Текст = "Не хватает "+ 
            (ВыборкаНоменклатура.Количество - 
            ВыборкаНоменклатура.КоличествоОстаток) +
            " позиций номенклатуры " + ВыборкаНоменклатура.Номенклатура + 
            ".";
            Сообщение.Сообщить();

            Отказ = Истина;
        КонецЕсли;

        Если Отказ Тогда
            Продолжить;
        КонецЕсли;

        // Создание движений
        ТекСебестоимость = 0;

        Если не ВыборкаНоменклатура.ЭтоУслуга Тогда

            ОсталосьСписать = ВыборкаНоменклатура.Количество;
            ВыборкаДетальныеЗаписи = ВыборкаНоменклатура.Выбрать();

            Пока (ОсталосьСписать > 0) И 
            ВыборкаДетальныеЗаписи.Следующий() Цикл
                Списываем = Мин(ОсталосьСписать,  
                ВыборкаДетальныеЗаписи.КоличествоОстаток);

                // регистр ОстаткиНоменклатуры Расход
                Движение = Движения.ОстаткиНоменклатуры.Добавить();
                Движение.ВидДвижения = ВидДвиженияНакопления.Расход;
                Движение.Период = Дата;
                Движение.Номенклатура = ВыборкаДетальныеЗаписи.Номенклатура;
                Движение.Партия = ВыборкаДетальныеЗаписи.Партия;
                Движение.Количество = Списываем;
                Движение.Стоимость = (Списываем * 
                ВыборкаДетальныеЗаписи.СтоимостьОстаток) /
                ВыборкаДетальныеЗаписи.КоличествоОстаток;

                ТекСебестоимость = ТекСебестоимость + Движение.Стоимость;
                ОсталосьСписать = ОсталосьСписать - Списываем;
            КонецЦикла;
        КонецЕсли;

        // регистр Продажи
        Движение = Движения.Продажи.Добавить();
        Движение.Период = Дата;
        Движение.Номенклатура = ВыборкаНоменклатура.Номенклатура;
        Движение.Количество = ВыборкаНоменклатура.Количество;
        Движение.Себестоимость = ТекСебестоимость;
        Движение.Выручка = ВыборкаНоменклатура.Сумма;
    КонецЦикла;

КонецПроцедуры

Займемся отчетами… Создадим отчет Продажи, добавим его в подсистему Оперативный учет, а затем на вкладке «Основные» нажмем кнопку «Открыть схему компоновки данных». В схему добавим набор данных вида «Запрос». Текст запроса легко можно создать визуальными средствами, но мы просто укажем его следующим образом:

ВЫБРАТЬ
	ПродажиОбороты.Номенклатура,
	ПродажиОбороты.КоличествоОборот КАК Количество,
	ПродажиОбороты.СебестоимостьОборот КАК Себестоимость,
	ПродажиОбороты.ВыручкаОборот КАК Продажа,
	ПродажиОбороты.ВыручкаОборот - ПродажиОбороты.СебестоимостьОборот 
	КАК Прибыль
ИЗ
	РегистрНакопления.Продажи.Обороты КАК ПродажиОбороты

Перейдем на закладку «Параметры». Установим параметры отчета согласно рисунка.

Перейдем на закладку «Настройки». Добавим в структуру нашего отчета новую группировку (клавиша Ins), но поле группировки указывать не будем (клавиша Enter). На вкладке «Выбранные поля» укажем список полей отчета, согласно требуемой формы.

Рядом с вкладкой «Выбранные поля» расположена вкладка «Параметры». Перейдем на нее и выполним настройку параметра «Период» отчета.

Последний штрих - переходим на вкладку «Другие настройки». Здесь зададим заголовок отчета.

Создадим отчет ОстаткиТоваров, добавим его в подсистему Оперативный учет, а затем на вкладке «Основные» нажмем кнопку «Открыть схему компоновки данных». В схему добавим набор данных вида «Запрос». Укажем следующий текст запроса:

ВЫБРАТЬ
	ОстаткиНоменклатурыОстатки.Номенклатура,
	ОстаткиНоменклатурыОстатки.Партия,
	ОстаткиНоменклатурыОстатки.КоличествоОстаток КАК Количество,
	ОстаткиНоменклатурыОстатки.СтоимостьОстаток КАК Стоимость
ИЗ
	РегистрНакопления.ОстаткиНоменклатуры.Остатки КАК 
	ОстаткиНоменклатурыОстатки

Перейдем на закладку «Ресурсы». Создадим ресурсы согласно рисунка, они нам необходимы потому, что в данном отчете присутствует группировка.

Перейдем на закладку «Параметры». Установим заголовок и состав даты параметра «Период».

Перейдем на закладку «Настройки». Добавим в структуру нашего отчета новую группировку (клавиша Ins), поле группировки - Номенклатура. Затем создадим вложенную в нее группировку, но для нее группировочное поле указывать не будем. На вкладке «Выбранные поля» укажем список полей отчета.

Рядом с вкладкой «Выбранные поля» расположена вкладка «Параметры». Перейдем на нее и выполним настройку параметра «Дата» отчета.

И последнее - переходим на вкладку «Другие настройки». Здесь зададим заголовок отчета, а также укажем прочие параметры, необходимые для формирования отчета в требуемом виде.

11) Привязка сообщения к элементу форму:
Прикрепление сообщения о нехватке товара при списании к столбцу Количество ТЧ Товары. Рекомендуется делать во всех случаях для доведения приема до автоматизма(одна из задач на УФ):

Сообщение. Текст = " Не хватает" + Выборка.Представление + " в количестве " + Число(Выборка.Количество - Выборка.КоличествоОстаток) ;
Сообщение. Поле = "Товары[" + (Выборка.НомерСтроки -1) + "].Количество";
Сообщение.УстановитьДанные(ЭтотОбъект);

*В модуле объекта обработки ЗаполнениеГрафика*

Процедура ЗаполнитьГрафик(ДатаНачала, ДатаОкончания, ВыходныеДни) Экспорт 

	Набор = РегистрыСведений.ГрафикиРаботы.СоздатьНаборЗаписей();
	Набор.Отбор.Подразделение.Установить(Подразделение);
	
	ЧислоСекундВСутках = 86400;
	Дат = ДатаНачала;
	
	Пока Дат <= ДатаОкончания Цикл
		Запись = Набор.Добавить();
		Запись.Дата = Дат;
		Запись.Подразделение = Подразделение;
		Если Найти(ВыходныеДни, Строка(ДеньНедели(Дат))) Тогда
			Запись.КоличествоЧасов = 0;
		Иначе	          
			Запись.КоличествоЧасов = 8;
		КонецЕсли; 
		Дат = Дат + ЧислоСекундВСутках;
	КонецЦикла; 
	Набор.Записать();
	
КонецПроцедуры

*В модуле объекта обработки ЗаполнениеГрафика при Сверхурочных часах*

Процедура ЗаполнитьГрафик(ДатаНачала, ДатаОкончания, ВыходныеДни, ОтражатьСверхурочные) Экспорт 
	
	Набор = РегистрыСведений.ГрафикиРаботы.СоздатьНаборЗаписей();
	Набор.Отбор.Подразделение.Установить(Подразделение);
	
	Набор.Прочитать();
	
	ЧислоСекундВСутках = 86400;
	
	Дат = ДатаНачала;
		
	Пока Дат <= ДатаОкончания Цикл
		Запись = Набор.Добавить();
		Запись.Дата = Дат;
		Запись.Подразделение = Подразделение;
		ДеньНедели = ДеньНедели(Дат);
		Если Найти(ВыходныеДни, Строка(ДеньНедели)) Тогда
			Запись.РабочихЧасов = 0;
		Иначе	          
			Запись.РабочихЧасов = 8;
		КонецЕсли; 
		
		Если ОтражатьСверхурочные И (ДеньНедели =2 ИЛИ ДеньНедели = 4) Тогда
			Запись.СверхурочныхЧасов = 3;
		КонецЕсли;
		
		Дат = Дат + ЧислоСекундВСутках;
	КонецЦикла; 
	Набор.Записать();
КонецПроцедуры

*В модуле объекта обработки ЗаполнениеГрафика при смене 1 через 3*

Процедура ЗаполнитьГрафик(ДатаНачала, ДатаОкончания, ВыходныеДни) Экспорт 
	
	Набор = РегистрыСведений.ГрафикиРаботы.СоздатьНаборЗаписей();
	Набор.Отбор.График.Установить(График);
	Набор.Прочитать();
	
	ЧислоСекундВСутках = 8640Текуща
	
	ТекущаяДата = ДатаНачала;
	Пока ТекущаяДата <= ДатаОкончания Цикл
		Запись = Набор.Добавить();
		Запись.Дата = ТекущаяДата;
		Запись.График = График;
		Запись.КоличествоЧасов = 24;
		ТекущаяДата = ТекущаяДата + 3 * 86400;
	КонецЦикла; 
	Набор.Записать();
КонецПроцедуры

*В модуле объекта обработки ЗаполнениеГрафика при обмене Автомобилми и дополнительному графику по пятидневки для расчета отпуска*

Процедура ЗаполнитьГрафик(ДатаНачала, ДатаОкончания, ВыходныеДни) Экспорт 
	Набор = РегистрыСведений.ГрафикиРаботы.СоздатьНаборЗаписей();
	Набор.Отбор.Автомобиль.Установить(Автомобиль);
	ЧислоСекундВСутках = 86400;
	Дат = ДатаНачала;
	
	Пока Дат <= ДатаОкончания Цикл
		Запись = Набор.Добавить();
		Запись.Дата = Дат;
		Запись.Автомобиль = Автомобиль;
		Если Найти(ВыходныеДни, Строка(ДеньНедели(Дат))) Тогда
			Запись.РабочихДней = 0;
		Иначе	          
			Запись.РабочихДней = 1;
		КонецЕсли; 
		
		Если ДеньНедели(Дат) < 6 Тогда
			Запись.ДнейПятидневки = 1;
		Иначе	
			Запись.ДнейПятидневки = 0;
		КонецЕсли;
		
		Дат = Дат + ЧислоСекундВСутках;
	КонецЦикла; 
	Набор.Записать();

	КонецПроцедуры

Для устранения ошибки нужно прописать установленный JAVA в переменные среды.

Проверить установлена ли JAVA можно в каталоге "C:\Program Files\1C\1CE\components"

Для доступа к переменным среды нужно перейти в Windows 11: Параметры - О системе - Дополнительные параметры системы.

В переменные среды жмем кнопку "Создать" и создаем новый параметр "JAVA_HOME" с указанием значения каталога, где установлена JAVA "C:\Program Files\1C\1CE\components\axiom-jdk-full-17.0.16+12-x86_64".

В системных переменных ищем переменную PATH, открываем найденную переменную. После того как откроется окно изменения переменной среды, создаем еще один параметр и прописываем пусть к JAVA "C:\Program Files\1C\1CE\components\axiom-jdk-full-17.0.16+12-x86_64".

После того как добавили переменную окружения и переменную среды перезапускаем 1С Предприятие Элемент Скрипт и пробуем выполнить скрипт. Возможно при первом выполнении скрипта появится окно Разрешения на запуск приложения JAVA, жмем Разрешить.

Как выгрузить данные из справочника в текстовый файл?

Текст = Новый ТекстовыйДокумент; 
Выборка = Справочники.Номенклатура.Выбрать(); 
Пока Выборка.Следующий() Цикл 
Стр = СтрЗаменить(Выборка.Наименование, Символ(34), "%квч%"); 
Код = Строка(Выборка.Код) + Символ(34); 
Текст.ДобавитьСтроку(Код + Стр); 
КонецЦикла; 
Текст.Записать("c:\temp\text.txt");

Как загрузить данные из текстового файла?

Текст = Новый ТекстовыйДокумент; 
Текст.Прочитать("c:\temp\text.txt"); 
Для НомерСтроки = 1 По Текст.КоличествоСтрок() Цикл 
Стр = Текст.ПолучитьСтроку(НомерСтроки); 
Позиция = Найти(Стр, Символ(34)); 
Код = Сред(Стр, 1, Позиция-1); 
прНаименование = Сред(Стр, Позиция + 1); 
Наименование = СтрЗаменить(прНаименование, "%квч%", Символ(34)); 
Сообщить(Код + "-" + Наименование); 
КонецЦикла;

Работа с текстом. Модель последовательного доступа

Путь = "c:\temp\text.txt"; 
Текст = Новый ЗаписьТекста(Путь, КодировкаТекста.UTF8); 
Выборка = Справочники.Номенклатура.Выбрать(); 
Пока Выборка.Следующий() Цикл 
Текст.ЗаписатьСтроку(Выборка.Наименование); 
КонецЦикла; 
Текст.Закрыть();

Путь = "c:\temp\text.txt"; 
Текст = Новый ЧтениеТекста(Путь, КодировкаТекста.UTF8); 
Стр = Текст.ПрочитатьСтроку(); 
Пока Стр <> Неопределено Цикл 
Стр = Текст.ПрочитатьСтроку(); 
Сообщить(Стр); 
КонецЦикла;

XML

Как из одной базы перенести документ в другую базу?

// Выгрузить в файл xml. 
ЗаписьXML=Новый ЗаписьXML(); 
ЗаписьXML.ОткрытьФайл("c:\doc.xml"); 
ЗаписьXML.ЗаписатьНачалоЭлемента("Root"); 
// Получить объект по ссылке. 
ВыгружаемыйОбъект=Документ.ПолучитьОбъект(); 
// С помощью средств сериализации записать объект в файл. 
ЗаписатьXML(ЗаписьXML,ВыгружаемыйОбъект); 
ЗаписьXML.ЗаписатьКонецЭлемента(); 
ЗаписьXML.Закрыть();

ЧтениеXML=Новый ЧтениеXML(); 
ЧтениеXML.ОткрытьФайл("c:\doc.xml"); 
// Текущим становится элемент Root. 
ЧтениеXML.Прочитать(); 
// Текущим становится элемент с документом. 
ЧтениеXML.Прочитать(); 
// Проверить сможет ли с данным значением "справиться" 
// система сериализации в данной базе. 
Если ВозможностьЧтенияXML(ЧтениеXML) Тогда 
// Получить ДокументОбъект.РеализацияТоваровУслуг 
ЗагружаемыйОбъект=ПрочитатьXML(ЧтениеXML); 
ЗагружаемыйОбъект.Записать(); 
КонецЕсли; 
ЧтениеXML.Закрыть();

Как можно сформировать XML-документ произвольной структуры?

Запись = Новый ЗаписьXML; 
Запись.ОткрытьФайл(ПутьКФайлу); 
Запись.ЗаписатьОбъявлениеXML(); 
Запись.ЗаписатьНачалоЭлемента("Корневой"); 
Запись.ЗаписатьАтрибут("Справочник", "Номенклатура"); 
Запись.ЗаписатьКомментарий("Краткая информация о номенклатуре"); 
Выборка = Справочники.Номенклатура.ВыбратьИерархически(); 
Пока Выборка.Следующий() Цикл 
Если Выборка.ЭтоГруппа Тогда 
Продолжить; 
КонецЕсли; 
Запись.ЗаписатьНачалоЭлемента("Элемент"); 
Запись.ЗаписатьАтрибут("Код", Строка(Выборка.Код)); 
Запись.ЗаписатьАтрибут("Артикул", Строка(Выборка.Артикул)); 
Запись.ЗаписатьТекст(Выборка.Наименование); 
Запись.ЗаписатьКонецЭлемента(); 
КонецЦикла; 
Запись.ЗаписатьКонецЭлемента(); 
Запись.Закрыть();

Как сформировать XML-документ в строку?

Запись = Новый ЗаписьXML(); 
Запись.УстановитьСтроку(); 
Запись.ЗаписатьОбъявлениеXML(); 
Запись.ЗаписатьНачалоЭлемента("Корневой"); 
Запись.ЗаписатьАтрибут("Справочник", "Номенклатура"); 
Запись.ЗаписатьКомментарий("Краткая информация о номенклатуре"); 
Выборка = Справочники.Номенклатура.ВыбратьИерархически(); 
Пока Выборка.Следующий() Цикл 
Если Выборка.ЭтоГруппа Тогда 
Продолжить; 
КонецЕсли; 
Запись.ЗаписатьНачалоЭлемента("Элемент"); 
Запись.ЗаписатьАтрибут("Код", Строка(Выборка.Код)); 
Запись.ЗаписатьАтрибут("Артикул", Строка(Выборка.Артикул)); 
Запись.ЗаписатьТекст(Выборка.Наименование); 
Запись.ЗаписатьКонецЭлемента(); 
КонецЦикла; 
Запись.ЗаписатьКонецЭлемента(); 
Стр = Запись.Закрыть(); 
Сообщить(Стр);

Как можно обмениваться данными, используя XML-сериализацию через файлы других форматов?

ЗаписьXML = Новый ЗаписьXML(); 
ЗаписьXML.УстановитьСтроку(); 
Данные = СсылкаНаДокумент.ПолучитьОбъект(); 
ЗаписатьXML(ЗаписьXML, Данные); 
ТекстСообщения = ЗаписьXML.Закрыть(); 
Текст = Новый ТекстовыйДокумент; 
Текст.УстановитьТекст(ТекстСообщения); 
Текст.Записать(ПутьКФайлу);

Текст = Новый ТекстовыйДокумент; 
Текст.Прочитать(ПутьКФайлу); 
ЧтениеXML = Новый ЧтениеXML(); 
ЧтениеXML.УстановитьСтроку(Текст.ПолучитьТекст()); 
Если ВозможностьЧтенияXML(ЧтениеXML) Тогда 
Данные = ПрочитатьXML(ЧтениеXML); 
Данные.Записать(); 
КонецЕсли;

Как можно загрузить XML документ произвольной структуры?

Чтение = Новый ЧтениеXML; 
Чтение.ОткрытьФайл(ПутьКФайлу); 
Пока Чтение.Прочитать() Цикл 
// Прочитать "структурные части" элементов. 
// Проверить, какая часть элемента - текущая. 
Если Чтение.ТипУзла = ТипУзлаXML.НачалоЭлемента Тогда 
ИмяУзла = Чтение.Имя; 
Сообщить("--" + ИмяУзла); 
// Атрибуты элементов можно читать только если текущая часть - 
// начало элемента 
Пока Чтение.ПрочитатьАтрибут() Цикл 
// Прочитать данные узла атрибута. 
ТипУзла = Чтение.ТипУзла; 
Имя = Чтение.Имя; 
Значение = Чтение.Значение; 
// Обработать полученные значения. 
КонецЦикла; 
ИначеЕсли Чтение.ТипУзла = ТипУзлаXML.Текст Тогда 
// В примере просто выводим текст в окно сообщений. 
Сообщить("Текст:" + Чтение.Значение); 
ИначеЕсли Чтение.ТипУзла = ТипУзлаXML.КонецЭлемента Тогда 
// В примере просто выводим признак конца элемента 
// в окно сообщений 
Сообщить("--Конец:" + Чтение.Имя); 
КонецЕсли; 
КонецЦикла;

DBF-файлы

Как можно построить выгрузку-загрузку посредством файлов DBF?

БД = Новый XBase; 
БД.Поля.Добавить("CODE", "S", 5); 
БД.Поля.Добавить("NAME", "S", 40); 
БД.СоздатьФайл(Путь + "start.dbf", Путь + "index.cdx"); 
БД.Индексы.Добавить("IDXCODE", "CODE"); 
ФлИБД = БД.СоздатьИндексныйФайл(Путь + "index.cdx"); 
БД.АвтоСохранение = Истина; 
Выборка = Справочники.Номенклатура.ВыбратьИерархически(); 
Пока Выборка.Следующий() Цикл 
БД.Добавить(); 
БД.CODE = Выборка.Код; 
БД.NAME = Выборка.Наименование; 
КонецЦикла; 
БД.ЗакрытьФайл();

БД = Новый XBase; 
БД.ОткрытьФайл(Путь + "start.dbf", Путь + "index.cdx"); 
БД.ТекущийИндекс = БД.Индексы.IDXCODE; 
Пока БД.Следующая() Цикл 
Сообщить(БД.CODE); 
Сообщить(БД.NAME); 
КонецЦикла; 
БД.ЗакрытьФайл();

Работа с HTML-документами

Заполнение HTML-анкет

Процедура URLПриИзменении(Элемент) 
ЭлементыФормы.ПолеHTML.Перейти(URL); 
КонецПроцедуры

Процедура ПолеHTMLДокументСформирован(Элемент) 
// Событие возникает и при открытии формы, когда в реквизите 
// URL содержится пустая строка. 
Если URL <> "" Тогда 
Док = ЭлементыФормы.ПолеHTML.Документ; 
// При попытке обратиться к несуществующему свойству 
// произойдет ошибка 
Док.forms["frm"].fam.Value = "Иванов"; 
Док.forms["frm"].nam.Value = "Иван"; 
Док.forms["frm"].otch.Value = "Иванович"; 
КонецЕсли; 
КонецПроцедуры

Работа с файлами

Как организовать диалог выбора текстового файла?

Режим = РежимДиалогаВыбораФайла.Открытие; 
ДиалогОткрытияФайла = Новый ДиалогВыбораФайла(Режим); 
ДиалогОткрытияФайла.ПолноеИмяФайла = ""; 
Фильтр = "Текст(*,txt)|*.txt"; 
ДиалогОткрытияФайла.Фильтр = Фильтр; 
ДиалогОткрытияФайла.МножественныйВыбор = Ложь; 
ДиалогОткрытияФайла.Заголовок = "Выберите файл"; 
Если ДиалогОткрытияФайла.Выбрать() Тогда 
ПутьКФайлу = ДиалогОткрытияФайла.ПолноеИмяФайла; 
КонецЕсли;

Режим = РежимДиалогаВыбораФайла.ВыборКаталога; 
ДиалогОткрытия = Новый ДиалогВыбораФайла(Режим); 
ДиалогОткрытия.Каталог = ""; 
ДиалогОткрытия.МножественныйВыбор = Ложь; 
ДиалогОткрытия.Заголовок = "Выберите каталог"; 
Если ДиалогОткрытия.Выбрать() Тогда 
ПутьККаталогу = ДиалогОткрытия.Каталог; 
КонецЕсли;

Как прочитать информацию о файле?

ДиалогОткрытияФайла = Новый ДиалогВыбораФайла(РежимДиалогаВыбораФайла.Открытие); 
ДиалогОткрытияФайла.Выбрать(); 
Файл = Новый Файл(ДиалогОткрытияФайла.ПолноеИмяФайла); 
Текст = "Файл: " + Файл.Имя; 
Текст = Текст + Символы.ПС + "Расширение: " + Файл.Расширение; 
Текст = Текст + Символы.ПС + "Полное имя: " + Файл.ПолноеИмя; 
Текст = Текст + Символы.ПС + "Путь: " + Файл.Путь; 
Текст = Текст + Символы.ПС + "Размер: " + Файл.Размер() + " байт"; 
Текст = Текст + ?(Файл.ПолучитьНевидимость(), Символы.ПС + "Невидимый. ", ""); 
Текст = Текст + ?(Файл.ПолучитьТолькоЧтение(), Символы.ПС + "Только чтение.", ""); 
Текст = Текст + Символы.ПС + "Последнее изменение: " + Файл.ПолучитьВремяИзменения(); 
Сообщить(Текст);

Как получить список файлов в указанном каталоге?

МассивНайденных = НайтиФайлы("C:\Обмен\Входящие", "*.xml"); 
Для Каждого Файл из МассивНайденных Цикл 
Сообщить(Файл.Имя); 
// Обработать найденные файлы. 
КонецЦикла;

Как переместить файл, выложенный на ftp к себе на локальный компьютер?

Если НайтиФайлы("C:\Temp\Sklad.xml") <> Неопределено Тогда 
УдалитьФайлы("C:\Temp\ Sklad.xml "); 
КонецЕсли; 
Если НайтиФайлы("ftp://111.222.333.4/Sklad.xml") <> Неопределено Тогда 
ПереместитьФайл("ftp://111.222.333.4/Sklad.xml", "C:\Temp\ Sklad.xml"); 
Сообщить("Файл перемещен."); 
Иначе 
Сообщить("Действие не выполнено. Файл в источнике не найден."); 
КонецЕсли;

Как разделить большой файл на несколько файлов определенного размера?

РазделитьФайл("D:/1/MyFile.xml", 1024*1024, "D:/1/11/");
ОбъединитьФайлы("D:/1/11/MyFile.xml.*", "D:/1/11/MyProg.exe");

Как поместить файлы в архив?

ФайлАрхива = Новый ЗаписьZipФайла("C:\Arch.zip", , , МетодСжатияZIP.Сжатие, УровеньСжатияZIP.Максимальный); 
ФайлАрхива.Добавить("C:\Inetpub\wwwroot\Applic1\*.*", РежимСохраненияПутейZIP.СохранятьОтносительныеПути, РежимОбработкиПодкаталоговZIP.ОбрабатыватьРекурсивно); 
ФайлАрхива.Записать();

ФайлАрхива = Новый ЧтениеZIPФайла("C:\Arch.zip"); 
ФайлАрхива.ИзвлечьВсе("C:\Open", РежимВосстановленияПутейФайловZIP.Восстанавливать); 
ФайлАрхива.Закрыть();

Как сравнить два текстовых файла?

ДиалогОткрытияФайла = Новый ДиалогВыбораФайла(РежимДиалогаВыбораФайла.Открытие); 
ДиалогОткрытияФайла.Фильтр = "Текстовый документ(*.txt)|*.txt"; 
// Выбрать первый файл. 
ДиалогОткрытияФайла.Заголовок = "Выберите первый файл:"; 
ДиалогОткрытияФайла.Выбрать(); 
ИмяФайла1 = ДиалогОткрытияФайла.ПолноеИмяФайла; 
// Выбрать второй файл. 
ДиалогОткрытияФайла.Заголовок = "Выберите второй файл:"; 
ДиалогОткрытияФайла.Выбрать(); 
ИмяФайла2 = ДиалогОткрытияФайла.ПолноеИмяФайла; 
// Сравнить выбранные файлы. 
СравнениеФайлов = Новый СравнениеФайлов(); 
СравнениеФайлов.ПервыйФайл = ИмяФайла1; 
СравнениеФайлов.ВторойФайл = ИмяФайла2; 
СравнениеФайлов.ИгнорироватьПустоеПространство = Истина; 
СравнениеФайлов.СпособСравнения = СпособСравненияФайлов.ТекстовыйДокумент; 
СравнениеФайлов.ПоказатьРазличия();

Как организовать контроль формирования файла внешним приложением?

Процедура ПроверкаНаличияФайла() 
ИмяКаталога = "c:\temp"; 
Маска = "*.xml"; 
НайденныеФайлы = НайтиФайлы(ИмяКаталога, Маска); 
Для Каждого Файл Из НайденныеФайлы Цикл 
Сообщить(Файл.Имя); 
КонецЦикла; 
КонецПроцедуры

ПодключитьОбработчикОжидания("ПроверкаНаличияФайла", 10);

ActiveX

Как использовать элементы управления ActiveX?

Режим = РежимДиалогаВыбораФайла.Открытие; 
ДиалогФыбораФайла = Новый ДиалогВыбораФайла(Режим); 
ДиалогФыбораФайла.Фильтр = "Все файлы (все)|*.*"; 
ДиалогФыбораФайла.Заголовок = "Выберите медиа файл"; 
Если ДиалогФыбораФайла.Выбрать() Тогда 
ПутьКМедиаФайлу = ДиалогФыбораФайла.ПолноеИмяФайла; 
// В зависимости от варианта объекта запись полного пути к файлу 
// производится либо в свойство FileName, либо в свойство URL. 
Попытка ЭлементыФормы.WMP.FileName = ПутьКМедиаФайлу; 
Исключение ЭлементыФормы.WMP.URL = ПутьКМедиаФайлу; 
КонецПопытки; 
КонецЕсли;

Макеты ActiveDocument

Как сформировать новый договор на основании файла Microsoft Word?

Договор = ПолучитьМакет("Договор"); 
// Получить объект из макета. 
MSWord = Договор.Получить(); 
НаименованиеКонтрагента = "ООО Торгуем всем"; 
Попытка 
Документ = MSWord.Application.Documents(1); 
Документ.Activate(); 
// Получить объект, который будем использовать для поиска и замены. 
Замена = Документ.Content.Find; 
// Заменить заранее определенные ключевые конструкции на требуемый текст. 
Замена.Execute("<НазваниеКомпании>", Ложь, Истина, Ложь, , , Истина, , Ложь, НаименованиеКонтрагента); 
// Далее аналогично для остальных ключевых конструкций. 
// Делаем видимым приложение и активизируем его. 
MSWord.Application.Visible = Истина; 
MSWord.Activate(); 
Исключение 
// Если произойдет ошибка выводятся данные об ошибке и объект закрывается. 
Сообщить(ОписаниеОшибки()); 
MSWord.Application.Quit(); 
КонецПопытки;

Работа с Интернет

Работа с электронной почтой

Как организовать работу с электронной почтой через установленного почтового клиента?

Почта = Новый Почта; 
Почта.Подключиться("login", "password"); 
Сообщ = Новый ПочтовоеСообщение; 
Сообщ.Текст = "Доброе время суток!!!!"; 
Сообщ.Тема = "Срочно в номер!!!"; 
Данные = Новый ДвоичныеДанные("c:\attach.txt"); 
Сообщ.Вложения.Добавить(Данные,"attach.txt"); 
Сообщ.Получатели.Добавить("hline@1c.ru"); 
Почта.Послать(Сообщ, Ложь); 
Почта.Отключиться();

Почта = Новый Почта; 
Почта.Подключиться("login", "password"); 
Выборка = Почта.Выбрать(Истина, Ложь); 
Для Каждого Сообщение Из Выборка Цикл 
Сообщить("Тема: " + Строка(Сообщение.Тема)); 
Сообщить("Текст: " + Строка(Сообщение.Текст)); 
Для Каждого Вложение Из Сообщение.Вложения Цикл 
Сообщить(Строка(Вложение.Наименование)); 
КонецЦикла; 
КонецЦикла;

Как организовать работу с почтой без установленного почтового клиента на компьютере пользователя?

// Сформировать почтовый профиль. 
// При отправке нет необходимости указывать настройки, связанные с POP сервером. 
ИПП = Новый ИнтернетПочтовыйПрофиль; 
ИПП.АдресСервераSMTP = Константы.АдресСервераSMTP.Получить(); 
ИПП.ВремяОжидания = Константы.ВремяОжидания.Получить(); 
ИПП.Пароль = Константы.Пароль.Получить(); 
ИПП.ПарольSMTP = Константы.ПарольSMTP.Получить(); 
ИПП.Пользователь = Константы.Пользователь.Получить(); 
ИПП.ПользовательSMTP = Константы.ПользовательSMTP.Получить(); 
ИПП.ПортSMTP = Константы.ПортSMTP.Получить(); 
// Создать сообщение. 
Сообщение = Новый ИнтернетПочтовоеСообщение; 
Сообщение.Получатели.Добавить("hline@1c.ru"); 
Сообщение.Отправитель.Адрес = "booktest@yandexyandex.ru"; 
Сообщение.Тема = "Срочно в номер!"; 
Сообщение.Тексты.Добавить("Доброе время суток!"); 
Вложение = Новый ДвоичныеДанные(ПутьКФайлуВложения); 
Сообщение.Вложения.Добавить(Вложение,"attach.txt"); 
// Подключиться и отправить. 
Почта = Новый ИнтернетПочта; 
Почта.Подключиться(Профиль); 
Почта.Послать(Сообщение); 
Почта.Отключиться();

// Формирование почтового профиля. 
// При получении нет необходимости указывать настройки, связанные с SMTP сервером. 
СостояниеПриема = "Подключение к серверу"; 
ИПП = Новый ИнтернетПочтовыйПрофиль; 
ИПП.АдресСервераPOP3 = Константы.АдресСервераPOP3.Получить(); 
ИПП.ВремяОжидания = Константы.ВремяОжидания.Получить(); 
ИПП.Пароль = Константы.Пароль.Получить(); 
ИПП.Пользователь = Константы.Пользователь.Получить(); 
ИПП.ПортPOP3 = Константы.ПортPOP3.Получить(); 
Соединение = Новый ИнтернетПочта; 
Соединение.Подключиться(ИПП); 
СостояниеПриема = "Получение выборки писем"; 
Выборка = Соединение.Выбрать(ЗабиратьССервера); 
СостояниеПриема = "Создание документов - писем"; 
КоличествоВВыборке = Выборка.Количество(); 
Индекс = 1; 
Для Каждого Письмо Из Выборка Цикл 
ТекПозиция = Окр(Индекс*100/КоличествоВВыборке); 
Если ТекПозиция <> Позиция Тогда 
Позиция = ТекПозиция; 
КонецЕсли; 
Док = Документы.Письмо.СоздатьДокумент(); 
Док.Тема = Письмо.Тема; 
СтрПолучатели = ""; 
Для Каждого Адрес Из Письмо.Получатели Цикл 
СтрПолучатели = СтрПолучатели + Адрес.Адрес + ","; 
КонецЦикла; 
Док.Получатели = СтрПолучатели; 
Если ТипЗнч(Письмо.Отправитель) = Тип("Строка") Тогда 
Отправитель = Письмо.Отправитель; 
Иначе Отправитель = Письмо.Отправитель.Адрес; 
КонецЕсли; 
Док.Отправитель = Отправитель; 
Содержание = ""; 
Для Каждого ТекстСообщения Из Письмо.Тексты Цикл 
Содержание = Содержание + ТекстСообщения.Текст + Символы.ПС; 
КонецЦикла; 
Док.Содержание = Содержание; 
Индекс = Индекс + 1; 
Док.Записать(); 
КонецЦикла; 
Соединение.Отключиться();

Выполнение HTTP запроса

СерверИсточник = HTTPserver; 
Адрес = "/price.asp"; 
ИмяВходящегоФайла = "c:\temp\input.html"; 
НТТР = Новый HTTPСоединение(СерверИсточник); 
НТТР.Получить(Адрес, ИмяВходящегоФайла); 
ВходящийФайл = Новый Файл(ИмяВходящегоФайла);

Работа с COM-объектами

Как из одной базы 1С:Предприятие 8.0 перенести остатки товаров в другую базу, используя COM-соединение.

Запрос = Новый Запрос; 
Запрос.Текст= "ВЫБРАТЬ 
| ОстаткиТоваровОрганизацийОстатки.Организация КАК Организация, 
| ОстаткиТоваровОрганизацийОстатки.Номенклатура, 
| ОстаткиТоваровОрганизацийОстатки.ГТДОрганизации, 
| ОстаткиТоваровОрганизацийОстатки.СтранаПроисхождения, 
| ОстаткиТоваровОрганизацийОстатки.Комиссионер, 
| ОстаткиТоваровОрганизацийОстатки.КоличествоОстаток 
|ИЗ 
| РегистрНакопления.ОстаткиТоваровОрганизаций.Остатки(&ДатаПереноса, ) КАК ОстаткиТоваровОрганизацийОстатки 
|ИТОГИ ПО 
| Организация"; 
Запрос.УстановитьПараметр("ДатаПереноса", ДатаПереноса); 
V8 = Новый COMОбъект("V8.ComConnector"); 
Попытка 
Открытие = V8.Connect("File=""" + Путь + """;Usr=""Usr1"";"); 
Исключение 
Предупреждение("База данных не открыта!!!"); 
Возврат; 
КонецПопытки; 
Выборка = Запрос.Выполнить().Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам); 
МенеджерДокумента = Открытие.Документы.ОприходованиеТоваров; 
МенеджерНоменклатуры = Открытие.Справочники.Номенклатура; 
МенеджерОрганизаций = Открытие.Справочники.Организации; 
// Менеджеры остальных справочников: 
Пока Выборка.Следующий() Цикл 
Документ = МенеджерДокумента.СоздатьДокумент(); 
Код = Выборка.Организация.Код; 
Организация = МенеджерОрганизаций.НайтиПоКоду(Код); 
Если Организация.Пустая() Тогда 
Организация = МенеджерОрганизаций.СоздатьЭлемент(); 
Организация.Код = Код; 
// Остальные реквизиты: 
Организация.Записать(); 
КонецЕсли; 
// Обработка остальных реквизитов, справочников: 
ВыборкаПодчиненная = Выборка.Выбрать(); 
Пока ВыборкаПодчиненная.Следующий() Цикл 
// Поиск/перенос данных справочников 
// заполнение табличной части документа 
КонецЦикла; 
Документ.Записать(РежимЗаписиДокумента.Проведение); 
КонецЦикла;

Как выполнить запрос к произвольной базе данных SQL?

стрПодключения = "Driver={SQL Server};" 
стрПодключения = стрПодключения + ИмяСервера + ";"; 
стрПодключения = стрПодключения +"Uid=" + ИмяПользователя + ";"; 
стрПодключения = стрПодключения + "Pwd=" + Пароль + ";"; 
стрПодключения = стрПодключения + "DataBase =" + ИмяБазы + ";"; 
стрПодключения = стрПодключения + "Pwd=" + Пароль + ";"; 
Connection = Новый COMОбъект("ADODB.Connection"); 
Connection.OpenServer = стрПодключения; 
RS = Новый COMОбъект("ADODB.Recordset"); 
// Запрос к базе на языке SQL запросов. 
RS.Open("Select * from TradeUnit", Connection); 
Пока RS.EOF() = 0 Цикл 
// Можно обращаться и обрабатывать значения полей выборки. 
ИД = RS.Fields("ID").Value; 
Код = RS.Fields("Code").Value; 
// Обработка других полей 
RS.MoveNext(); 
КонецЦикла; 
RS.Close(); 
Connection.Close();

Отформатированные примеры из раздела "Интеграции" статьи https://infostart.ru/1c/articles/19343/

• Символ табуляции "│" (code 2502)
• Цвет конструкции "Прочее" стиль: Линия отчета #CCC085

2. Шрифт :

• JetBrains Mono, 10 (https://www.jetbrains.com/lp/mono/)

3. Текущий идентификатор:

• Стиль: Цвет активности #FACC1F