Сегодня затронем тему текстов в CLEO скриптинге.
Тексты в CLEO бывают разных видов: субтитры, текст бокс, стилизованный текст (его можно увидеть при выполнении миссии, смерти игрока, или на гонках).

Рассмотрим опкоды, выводящие различные типы текста на экран:

0ACD: show_text_highpriority "text" time 100

Данный опкод выводит текст-субтитры внизу экрана. Вместо "text" нужно писать свой текст, переведенный через rus2gxtcoder. Time - время отображения текста на экране. Данный опкод имеет высокий приоритет, то есть если на экране будут другие субтитры (например в миссии), то они будут убраны, а текст со скрипта будет выведен на экран.

0ACC: show_text_lowpriority "text" time 100

Точно такой же опкод как и предыдущий, но имеет низкий приоритет. Если на экране будут показаны другие субтитры, то скрипт будет ждать пока они закончатся, и только потом выведет нужный текст.

Для вывода некоторых текстов нужно сначала создать динамическую gxt запись

0ADF: add_dynamic_GXT_entry "NAME" text "Text"

NAME - это имя записи. Оно должно быть не более 5 символов
Text - соответственно текст, который будет храниться в записи

Если текстовая запись вам больше не нужна, чтобы не засорять память игры удалить её можно опкодом 0AE0: remove_dynamic_GXT_entry "NAME"




Данный опкод выводит постоянный текст-бокс с текстом из gxt записи NAME, которую мы создали ранее.

0512: show_permanent_text_box 'NAME'

Чтобы убрать текст бокс, нужно воспользоваться опкодом 03E6: remove_text_box

Этот опкод выведет на экран форматированный текст бокс. Он будет выведен на экран всего на пару секунд, а потом сам исчезнет.

0ACE: show_formatted_text_box "Text %d" 1@

Как вы заметили, в опкоде стоит символ %d и переменная 1@. Так вот, у форматированных текстов есть одна особенность - в них можно выводить данные из переменной. %d - это тип переменной, а 1@ - переменная, число из которой нужно вывести на экран.

Типы переменных для добавления в текст:
%d - целое число
%f - дробное
%s - строка

Если мы напишем такой код:

1@ = 333
0ACE: show_formatted_text_box "Text %d" 1@

В игре на экран будет выведена запись "Text 333"

Если напишем такой:

1@ = 333.333
0ACE: show_formatted_text_box "Text %f" 1@

То будет выведен текст "Text 333.333"

По такому же принципу работают следующие опкоды:

0ACF: show_formatted_styled_text "This is %.4X opcode" time 2000 style 1 0x0ACF
0AD0: show_formatted_text_lowpriority "This is %.4X opcode" time 2000 0x0AD0
0AD1: show_formatted_text_highpriority "This is %.4X opcode" time 2000 0x0AD1

Просто подставляете в конце вместо 0x0AD0 переменную и в тексте указываете тип. Можно добавлять несколько переменных, одну за другой.

Например так:

1@ = 1
2@ = 10
0ACE: show_formatted_text_box "%d Text %d" 1@ 2@

Результат: "1 Text 10"

В данных опкодах не обязательно выводить переменные. Если вам это не нужно, просто удалите символы 0x0ACF в конце.

Аналоги этих же опкодов, но они берут текст из gxt записи.

00BB: show_text_lowpriority GXT 'IE23' time 3000 flag 1 
00BC: show_text_highpriority GXT 'MTIME3' time 1000 flag 1

Стилизованный форматированный текст:

0ACF: show_formatted_styled_text "Text" time 2000 style 1 0x0ACF

Значения style:
1 - текст по середине, как при провале миссии
2 - текст выводится, где название миссии
3 - текст как при аресте или смерти игрока
4 - сверху, как в гоночных миссиях
6 - по центру, как в гоночных миссиях
7 - как при провале миссии, но уже вверху

Стилизовнный текст из gxt записи:

00BA: show_text_styled GXT "BEEFY" time 1000 style 2  

Если урок был вам непонятен, рекомендую ознакомиться с уроком по текстам от wmysterio. А на этом все!

Урок "Работа с текстом" от wmysterio

Тут вы можете найти шаблоны для CLEO скриптов, которые можно отредактировать и использовать в своих миссиях.

Шаблон для добавление любого действия во время цели

Нервометр для актера

Добавляем метку на карту во время цели

Одноразовое нитро для машины

Полезные ссылки:

CLEO: Урок 1 - Основы

База данных опкодов

Если вы проходили оригинальные миссии GTA SA, вы наверняка знаете, что такое нервометр. Но если кто не в курсе, нервометр - это такой датчик приближения в игре.

Действует он так: если мы подойдем очень близко к цели (актеру/объекту/машине), то шкала нервометра начнет повышаться и миссия провалится. Так же миссия будет провалена, если мы ушли слишком далеко от цели.

Сегодня попробуем сделать упрощенную версию нервометра для своей миссии. Мы не будем создавать шкалу приближения, а просто будем выводить предупреждение в виде текста, что игрок подошел слишком близко к цели, и если игрок не уйдет из зоны поражения - миссия провалится. А если игрок окажется слишком далеко от цели, то миссия сразу же будет провалена без предупреждения.

Если вы не читали предыдущий урок, обязательно прочитайте его, чтобы понимать принцип взаимодействия DYOM и CLEO.

И так, приступим. Создаем скрипт, и добавляем 3 условия при которых будет работать наш нервометр

{$CLEO}
0000:

:NERVOMETR
wait 0
if and
$ONMISSION == 1 //миссия запущена
$10914 == 1 //слот миссии равен 1
$9903 == 0 //текущая цель равна 0
jf @NERVOMETR

Далее добавляем такое условие:

if
0AE1: 0@ = random_actor_near_point 2469.8926 -1657.8087 13.3443 in_radius 1.0 find_next 0 pass_deads 1
jf @NERVOMETR
wait 500

Данный опкод записывает рандомного актера в точке 2469.8926 -1657.8087 13.3443 с радиусом 1 в переменную 0@. Так же этот опкод работает и как проверка существует ли актер. Если актер существует, то ждем 500 мс и идем дальше по скрипту, если нет - возвращаемся в начало.

Вместо координат 2469.8926 -1657.8087 13.3443 вам нужно вставить координаты актера для которого будет действовать нервометр. Для этого зайдите в игру, встаньте на то место, где стоит нужный актер, сверните игру и зайдите в Sanny Builder. Теперь поставьте курсор туда, куда нужно вставить координаты и нажмите CTRL+SHIFT+C.

Дальше создаем цикл while, который будет повторяться пока текущей целью является цель №1.
Добавляем условие, если актер 0@ не находится около игрока в радиусе 50 единиц, то завершаем миссию, выводим текст "Цель ушла" большими буквами, как при провале миссии, и выходим из цикла с помощью break.
Текст для CLEO скриптов нужно переводить через rus2gxtcoder, либо писать на языке мефисто, иначе у вас в игре вместо нормального текста будет не пойми что.

while $9903 == 0
wait 0
    if
    80F2:   not actor 0@ near_actor $PLAYER_ACTOR radius 50.0 50.0 sphere 0
    then
    045C: abort_mission
    0ACF: show_formatted_styled_text "~r~‰eћ© yҐћa" time 2000 style 1 //"~r~‰eћ© yҐћa" - текст, time - время появления текста, style - стиль текста
    break
    end

Отлично, пол дела сделано. Теперь если цель отдалится от игрока более чем на 50 единиц, то миссия будет завершена с надписью "Цель ушла"

Дальше нам потребуется написать код, который будет завершать миссию и в том случае, если игрок находится слишком близко к цели.

Для этого добавляем следующее условие (все так же в цикле): если актер около игрока в радиусе 10 единиц, то выводим текст "Вы слишком близко" на 2 секунды.

    if
    00F2:   actor 0@ near_actor $PLAYER_ACTOR radius 10.0 10.0 sphere 0
    then
    0ACD: show_text_highpriority "‹¨ cžœ¥ko¯ —žœŸko" time 2000 

Ждем 4 секунды и еще раз проверяем находится ли актер 0@ около игрока в радиусе 10 единиц. Это нужно для того, чтобы после появления предупреждения у игрока было немного времени и он мог бы отойти от цели на определенное расстояние, чтобы избежать провала миссии. Если игрок все еще остался в этом радиусе, то завершаем миссию, выводим текст "Вас заметили" и прерываем цикл с помощью break. Не забываем закрыть все открытые условия с помощью end

    wait 4000
        if
        00F2:   actor 0@ near_actor $PLAYER_ACTOR radius 10.0 10.0 sphere 0
        then
        045C: abort_mission
        0ACF: show_formatted_styled_text "~r~‹Ё џaЇe¤e®Ё" time 2000 style 1
        break
        end
    end  

Пишем последние две строчки кода. Закрываем открытый ранее цикл while и переходим в начало скрипта.

end 
jump @NERVOMETR

Вот, что у нас получилось в итоге:

{$CLEO}
0000:

:NERVOMETR
wait 0
if and
$ONMISSION == 1
$10914 == 1
$9903 == 0
jf @NERVOMETR
wait 500
if
0AE1: 0@ = random_actor_near_point 2469.8926 -1657.8087 13.3443 in_radius 1.0 find_next 0 pass_deads 1
jf @NERVOMETR
wait 500
while $9903 == 0
wait 0
    if
    80F2:   not actor 0@ near_actor $PLAYER_ACTOR radius 50.0 50.0 sphere 0
    then
    045C: abort_mission
    0ACF: show_formatted_styled_text "~r~‰eћ© yҐћa" time 2000 style 1
    break
    end
    if
    00F2:   actor 0@ near_actor $PLAYER_ACTOR radius 10.0 10.0 sphere 0
    then
    0ACD: show_text_highpriority "‹Ё cћњҐkoЇ —ћњџko" time 2000
    wait 4000
        if
        00F2:   actor 0@ near_actor $PLAYER_ACTOR radius 10.0 10.0 sphere 0
        then
        045C: abort_mission
        0ACF: show_formatted_styled_text "~r~‹Ё џaЇe¤e®Ё" time 2000 style 1
        break
        end
    end
end 
jump @NERVOMETR

Заходим в игру и смотрим результат. Наш скрипт прекрасно работает.

Приветствую! Сегодня поговорим о взаимодействии CLEO скриптов и DYOM.

Если вы хоть раз делали миссии в DYOM, то вы наверняка знаете, что функционал в нем ограничен. Например, в миссиях нельзя добавить актерам анимацию разговора по телефону, добавить стрельбу из машины от первого лица, добавить диалог во время поездки к чекпоинту и многое многое другое.

В этом случае нам поможет знание CLEO скриптинга, ведь именно благодаря скриптам мы можем добавить в свою миссию те функции, которых так не хватает в DYOM.

Прежде чем мы приступим к написанию и разбору скрипта, вспомним о глобальных переменных. Глобальная переменная - это контейнер, в котором хранятся какие-либо данные. Считывать и изменять их мы можно любым CLEO скриптом. Так вот, взаимодействие DYOM и CLEO возможно именно благодаря глобальным переменным.

Пример:
Нам нужно чтобы во время миссии игрок умер на цели №30. Каким образом наш скрипт узнает, когда именно текущей целью станет цель №30, чтобы именно в этот момент убить игрока? Можно, конечно, просто проверить находится ли игрок в определенной точке, но мы пойдем более надежным и простым путем.
Вот тут нам и понадобятся глобальные переменные из кода DYOM (посмотреть их можно тут).

$9903 - данная переменная хранит номер текущей цели на миссии. И если мы хотим узнать, является ли цель №30 текущей, то нам нужно создать проверку $9903 == 29. Почему 29, а не 30? Потому что цели в DYOM отсчитываются не с первой, а с нулевой. Поэтому при проверке цели надо указывать число на 1 единицу меньше.

Выглядит это все следующим образом:

if
$9903 == 29
then
...наш код...
end

И так, теперь давайте напишем скрипт, который будет добавлять в нашу миссию эффект пьяной камеры как в GTA 4 во время цели №4.

Какие переменные нам для этого понадобятся:
$10914 - номер слота текущей миссии (от 1 до 8)
$9903 - номер текущей цели на миссии

Как всегда создаем скрипт, добавляем метку и задержку 0 мс

{$CLEO}
0000:

:DRUNK
wait 0

Далее нам необходимо будет добавить 3 условия:
1) миссия запущена (переменная $ONMISSION)
2) слот миссии равен 1 (переменная $10914)
3) цель миссии равна 3 (переменная $9903)

if and
$ONMISSION == 1
$10914 == 1
$9903 == 3

Теперь создаем цикл, который будет выполняться пока текущая цель будет равна 3. Далее добавляем wait 0, в циклах while это обязательно.

После этого добавим опкод 052C: set_player $PLAYER_CHAR drunk_visuals 100, который создает эффект пьяной камеры с интенсивностью тряски 100 (число можно установить свое). Закрываем цикл опкодом end.
После завершения цикла (текущая цель не равна 3), убираем эффект пьяной камеры. Добавляем еще один end для закрытия условия, которое мы открыли в предыдущем куске кода.

then
    while $9903 == 3
    wait 0
    052C: set_player $PLAYER_CHAR drunk_visuals 100
    end
    052C: set_player $PLAYER_CHAR drunk_visuals 0   
end

В конце добавляем jump @DRUNK для того, чтобы скрипт повторялся.

И так, для чего мы добавили цикл? Можно же было просто написать так:

:DRUNK
wait 0
if and
$ONMISSION == 1
$10914 == 1
$9903 == 3
then
052C: set_player $PLAYER_CHAR drunk_visuals 100
else 
052C: set_player $PLAYER_CHAR drunk_visuals 0  
end
jump @DRUNK

Но так писать скрипт неправильно. Почему? Потому что если хотя бы одно условие не будет верным, то начнет выполняться опкод 052C: set_player $PLAYER_CHAR drunk_visuals 0 . То есть он будет постоянно работать, если цель не равна 3 (на цели 1, 2, 4, 5 и так далее). А зачем нам убирать пьяную камеру, когда она еще даже не включилась? Так же этот опкод будет постоянно работать если миссия выключена или если слот миссии не равен 1. Нам такое не нужно. Это лишняя работа для скрипта, от которой можно легко избавиться.

Если мы добавим цикл, все сразу станет работать так, так нужно. Ведь в цикл мы попадаем лишь один раз: если миссия запущена, слот миссии равен 1 и цель равна 3. Соответственно и выходим мы из него только 1 раз. Значит опкод отключения пьяной камеры выполнится тоже лишь однажды за миссию.

В итоге у нас получился вот такой скрипт:

{$CLEO}
0000:

:DRUNK
wait 0
if and
$ONMISSION == 1
$10914 == 1
$9903 == 3
then
    while $9903 == 3
    wait 0
    052C: set_player $PLAYER_CHAR drunk_visuals 100
    end
    052C: set_player $PLAYER_CHAR drunk_visuals 0   
end
jump @DRUNK

Попробуйте создать миссию из 5 целей, сохраните её на 1 слот и проверьте работает ли получившийся скрипт. Пьяная камера должна включиться на цели 4 и отключиться во время цели 5.

Надеюсь, урок был для вас полезен. А на этом все!

Sanny Builder

Среда разработки новых миссий и скриптов для серии игр GTA 3D.

Rus2gxtCoder

Программа для написания текстов к скриптам.

Антизависон

Данная программа закрывает игру нажатием клавиши F5. Очень полезная вещь, спасает даже если игра намертво зависла.

GTA Animation Manager

Программа для просмотра всех анимаций в GTA.

Power Script Helper v 1.0

Программа содержит в себе множество уроков по скриптингу, а так же другую полезную информацию для разработки: коды клавиш, id оружия, id цветов транспорта, иконки, интерьеры и многое другое.

ЛКМ - 1
ПКМ - 2
Колесико(не скролл) - 4
XButton1 - 5
XButton2 - 6

A - 65
B - 66
C - 67
D - 68
E - 69
F - 70
G - 71
H - 72
I - 73
J - 74
K - 75
L - 76
M - 77
N - 78
O - 79
P - 80
Q - 81
R - 82
S - 83
T - 84
U - 85
V - 86
W - 87
X - 88
Y - 89
Z - 90

1 - 49
2 - 50
3 - 51
4 - 52
5 - 53
6 - 54
7 - 55
8 - 56
9 - 57
0 - 48

NUM Key
1 - 97
2 - 98
3 - 99
4 - 100
5 - 101
6 - 102
7 - 103
8 - 104
9 - 105
0 - 96
* - 106
+ - 107
- (Минус) - 109
/ - 111
. - 110

F1 - 112
F2 - 113
F3 - 114
F4 - 115
F5 - 116
F6 - 117
F7 - 146
F8 - 119
F9 - 120
F10 - 121
F11 - 122
F12 - 123

Backspace - 8
Tab - 9
Enter - 13
Shift - 16
Ctrl - 17
Pause - 19
CapsLock - 20
Esc - 27
Space - 32
Page Up - 33
Page Down - 34
End - 35
Home - 36
Insert - 45
Delete - 46
Scroll Lock - 145
Num Lock - 144

$8271 - запущен ли DYOM (1 - да, 0 - нет)

$8274 - включен ли режим сторилайна (1 - да, 0 - нет)

$9903 - номер текущей цели на миссии. Значение должно быть меньше на 1. То есть, вместо 2 указывайте 1, вместо 3 - 2 и так далее

$10294($9903,101i) - тип текущей цели на миссии (типы целей смотрите ниже)

$10916 - количество целей в миссии

$10914 - номер слота загруженной миссии

$9878 - название загруженной миссии

$9879 - автор миссии

v$9905 - аудиокод миссии (в формате SD/ABCDE/xx.mp3)

$9889 - тексты всех целей

$11447 $11448 $11449 - координаты цели 0 (игрок)

Типы целей:

• 2 - чекпоинт
• 5 - актер
• 6 - катсцена
• 7 - телепорт
• 10 - таймаут
• 11 - погода
• 12 - время
• 13 - появление пешеходов/машин
• 14 - уровень розыска
• 17 - убрать оружие у игрока
• 18 - разговор по телефону
• 20 - дать денег игроку
• 22 - анимация игрока

Что такое цикл в скриптинге? Цикл - это часть кода которая повторяется указанное количество раз, либо повторяется пока верно указанное условие. Циклы являются очень важной частью в скриптинге, поэтому вам стоит о них знать.

Виды циклов

Цикл while

while 0256:   player $PLAYER_CHAR defined
wait 0
0826: enable_hud 0
end

Данный цикл будет повторять код до тех пор, пока игрок существует (0256: player $PLAYER_CHAR defined). В данном случае он убирает HUD. Когда игрок перестанет существовать, то скрипт продолжит движение вниз по коду.

В цикле while обязательно нужно ставить задержку wait 0 так как он будет повторяться неопределенное количество раз.

Но что делать если мы хотим, чтобы HUD убирался когда игрок НЕ существует? Для этого нужно использовать отрицательные опкоды. Чтобы написать отрицательный опкод, нужно взять обычный опкод, заменить 0 в начале на 8 и добавить not перед его описанием

Из такого опкода:

0256:   player $PLAYER_CHAR defined

У нас получится такой:

8256:   not player $PLAYER_CHAR defined

Цикл while true

while true
wait 0
0826: enable_hud 0
end

Данный цикл будет повторяться бесконечно, пока мы вручную его не остановим с помощью опкода break. О нем поговорим чуть позже.

Цикл for

for 0@ = 0 to 100
0826: enable_hud 0
end

Этот цикл повторяет код указанное количество раз, в нашем случае 101 раз (от 0 до 100). Переменная 0@ (можно поставить любую другую) в данном цикле нужна, чтобы хранить количество повторений, без нее ничего не будет работать и при компиляции скрипта вы получите ошибку.

Как вы могли заметить, тут я не написал wait 0. Почему? Потому что данный цикл будет повторяться известное нам количество раз - 101, и отсутствие задержки не приведет к зависанию игры. Конечно, без wait 0 код будет выполняться очень быстро и hud пропадет всего на какие-то доли секунды, поэтому в данном случае лучше добавить задержку.

Прерывание цикла

Прервать цикл можно опкодом break

while 0256:   player $PLAYER_CHAR defined
wait 0
0826: enable_hud 0
   if
   08FE:   text_box_displayed
   then
   break
   end
end

Как вы заметили, внутри цикла я добавил условие появился ли на экране текст бокс. Теперь цикл прервется в двух случаях: 1) если игрок не существует 2) если показан текст-бокс на экране. Опкод break можно использовать как в циклах while, так и в циклах for.

P.S. Отступы как у меня в коде делать не обязательно, Sanny Builder не чувствителен к ним. Отступы делаются для удобства и улучшения читабельности кода.

И так, теперь немного практики. Давайте напишем небольшой скрипт, который будет отнимать жизни у игрока в том случае, если он не удерживает клавишу W.

{$CLEO .cs}
0000:

:HEALTH
wait 0
while 8AB0:   not key_pressed 87
wait 0
    if 
    0256:   player $PLAYER_CHAR defined
    then
        wait 300
        0226: 0@ = actor $PLAYER_ACTOR health
        0@ -= 1
        0223: set_actor $PLAYER_ACTOR health_to 0@
    end
end
jump @HEALTH

Разберем код:

1) По классике создаем метку и пишем wait 0
2) Создаем цикл while с условием "если не нажата клавиша 87"
Каждая клавиша на клавиатуре имеет свой номер, в данном случае 87 - это клавиша W. Номера всех клавиш можно посмотреть тут.

3) Пишем wait 0 в начале цикла, чтобы игра не зависла
4) Создаем внутри цикла условие "существует ли игрок". Это нужно для того, чтобы здоровье не отнималось когда игрок умер или арестован.
5) Если игрок существует, добавляем задержку 300 миллисекунд, иначе здоровье будет отниматься слишком быстро
6) Записываем здоровье игрока в переменную 0@
7) Отнимаем от переменной 0@ 1 единицу
8) Устанавливаем игроку количество здоровья в виде переменной 0@
9) Возвращаемся на метку HEALTH, если цикл прерван

Таким образом мы создали скрипт, который будет отнимать 1 единицу здоровья игрока каждые 300 миллисекунд, если не нажата клавиша W.
Получается, с помощью скрипта мы заставим игрока постоянно двигаться. Если он остановиться, то начнет умирать. Чем-то напоминает фильм "Адреналин", да?

Конечно, в скрипте есть недочет. Если вы будете использовать его для своих миссий, то здоровье игрока будет отниматься во время катсцен и во время создания самой миссии (если вы создаете миссию в DYOM). Вам нужно уметь просчитывать такие моменты, это очень важно.

Чтобы это предотвратить, нужно добавить еще 2 условия:

{$CLEO .cs}
0000:

:HEALTH
wait 0
while 8AB0:   not key_pressed 87
wait 0
    if and
    $ONMISSION == 1 //если запущена миссия
    09E7:   player $PLAYER_CHAR not_frozen //если игрок не заморожен игрой 
    0256:   player $PLAYER_CHAR defined 
    then
        wait 300
        0226: 0@ = actor $PLAYER_ACTOR health
        0@ -= 1
        0223: set_actor $PLAYER_ACTOR health_to 0@
    end
end
jump @HEALTH

Что мы добавили в код:
1)$ONMISSION == 1 проверка запущена ли миссия
2) 09E7: player $PLAYER_CHAR not_frozen проверка не обездвижен ли игрок.
Как мы знаем, во время катсцен игрок обездвиживается, поэтому здоровье не будет отниматься в этом случае.

Теперь скрипт будет работать как надо, и здоровье будет отниматься только тогда, когда мы можем управлять игроком во время миcсии.

Вот и всё, теперь вы научились использовать циклы в CLEO скриптах, поздравляю!

К следующему уроку ->

Полезные ссылки

Номера клавиш в CLEO
Урок "Циклы - Часть 1" от wmysterio
Урок "Циклы - Часть 2" от wmysterio

Сегодня мы попробуем написать первый полноценный CLEO-скрипт, используя знания, полученные на прошлом уроке. Наш скрипт должен будет завершать запущенную миссию, если здоровье игрока станет меньше 50.

И так, пишем две строки с которых начинается любой CLEO-скрипт

{$CLEO}
0000:

Наш скрипт будет повторяться бесконечно, поэтому 0A93: end custom thread в конце писать не нужно.

Теперь добавляем метку START и добавляем задержку wait 0, чтобы игра не зависла

{$CLEO}
0000:

:START
wait 0

Далее нужно написать условие, при которых скрипт будет завершать миссию. Напишем условие: если миссия запущена и игрок существует, то идем дальше по скрипту, если нет - возвращаемся на метку START.

if and
$ONMISSION == 1 
0256:   player $PLAYER_CHAR defined
jf @START

Отлично, условие написано, теперь нужно добавить действия, которые будут выполнены, если условие верно.

0226: 1@ = actor $PLAYER_ACTOR health
if
1@ < 50
jf @START
045C: abort_mission
wait 5000

И так, что мы делаем в данном куске кода:
1) Записываем текущее здоровье игрока в переменную 1@
К сожалению в CLEO нельзя сразу проверить здоровье актера одним опкодом, например так:
actor $PLAYER_ACTOR health < 50
Поэтому придется сначала записать здоровье в переменную, а уже потом проверять переменная меньше 50 или нет.
2) Добавляем проверку на то, что переменная 1@ (здоровье) меньше 50
3) Если условие не верно и переменная больше 50, то возвращаемся на метку START
4) Если верно - завершаем миссию
5) Добавляем задержку 5 секунд, чтобы скрипт подождал пока миссия завершится

Теперь нам нужно сделать так, чтобы скрипт постоянно повторялся. Чтобы миссия завершалась каждый раз, когда здоровье игрока будет меньше 50.

Для этого в конце добавим опкод возвращения на метку START.

jump @START

Если мы добавим 0A93: end_custom_thread вместо jump @START, то скрипт отключится сразу после того, как будет завершена миссия. Заново он начнет работать только после перезагрузки игры.

Вот что у нас получилось в итоге:

{$CLEO}
0000:

:START
wait 0
if and
$ONMISSION == 1 
0256:   player $PLAYER_CHAR defined
jf @START
0226: 1@ = actor $PLAYER_ACTOR health
if
1@ <= 50
jf @START
045C: abort_mission
jump @START

Теперь нажимаем вкладку Запуск/Компилировать или жмем клавишу F6. Далее выбираем путь до папки CLEO в GTA SA.
Вот и всё, скрипт создан и установлен в игру. Найти его можно в папке CLEO.

Последний шаг. Запустите игру и проверьте работает ли скрипт. Если он не работает - внимательно сверьте код в статье и тот, что вы написали, наверняка найдете ошибку.
Если скрипт работает - поздравляю! Вы уже на шаг ближе к пониманию устройства CLEO скриптов (Вы же не просто скопировали и вставили весь код, да? МММмм?)

Надеюсь, вам все было понятно. До следующего урока!

К следующему уроку ->

Небольшой совет о том, как сделать так, чтобы актер перелезал через забор в катсцене.

На самом деле, сделать это очень просто. Для этого нужно поместить с одной стороны препятствия игрока, а с другой поставить актера с дружественным отношением и поведением "следует за игроком". Таким образом, во время катсцены актер побежит к игроку и перелезет через забор. Таким же образом можно заставить актера плыть по воде или вскарабкаться на крышу (правда с этим могут возникнуть проблемы).