Сценарий быстрой загрузки AnyDesk (batch)

В телеграмм https://t.me/PS_crutch

Бывает что на том конце совсем "всё сложно", и тогда можно кинуть человеку в почту батник.

Почему не PoSh скрипт? Потому что в таком случае человек будет вынужден включить выполнение сценариев на компьютере, а то и повыситься в правах, что не совместимо с понятием "всё сложно".

Если кому то надо, этот автор написал подобное на PoSh , назвав это "бэкдором". Не знаю кто в нашей современности сидит под админом или рутом.. 🤔

Вернемся к нашему изделию.

Первым делом скрипт проверяет наличие установленного в системе AnyDesk. В случае когда AnyDesk уже установлен в систему, мы получаем ID.

В случае, если обнаружить по стандартным путям установки AnyDesk не удалось, скрипт выполняет загрузку Anydesk.exe с сайта разработчика на рабочий стол, затем запускает его так же сообщает ID в CMD

Что может быть полезным, так это в особо "сложных" случаях можно например не только отобразить ID AnyDesk, но и отправить его например в телеграмм бота.

Вместо XXX укажите ваш токен и чат ID.

curl "https://api.telegram.org/botXXX:XXX/sendMessage?chat_id=XXX&text="%ID%

В качестве

text=

можно указать например имя пользователя

%username%

или имя компьютера

%computername%

Разумеется с распространением вашего токена он будет скомпрометирован, но токен так же несложно сменить, как и удалить бота в телеграмм.

Все консольные команды AnyDesk приведены на сайте разработчика тут и тут

Код целиком:

rem ********************************
rem Anydesk fast downloading script
rem Firstly it checkin for installed anydesk and if it's does not exist it downloading Anydesk onto the user's Desktop
rem Secondary it gets Anydesk ID and display it on the screen and send this anydesk ID onto your telegram bot
rem Official Anydesk Page https://support.anydesk.com/knowledge/command-line-interface-for-windows
rem (c) Alexander Kucherov 2024 https://t.me/PS_crutch https://teletype.in/@ps_crutch
rem To send Anydesk ID to your telegram bot pls remove rem and replace XXX by your token and chat id
rem ********************************
title=AnyDeskDownload
@echo off
Mode con cols=100 lines=30
echo Checking file structure.. Patience pls
if exist "C:\Program Files (x86)\AnyDesk\AnyDesk.exe" (
         goto :ok
) else goto :download

:download
cls
color 0E
echo Downloading missing files. Wait for a moment pls
TimeOut /T 3 /NoBreak>Nul
CHCP 1251 >Nul
for /f "usebackq tokens=1,2,*" %%B IN (`reg query "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders" /v Desktop`) do set DESKTOP=%%D
CHCP 866 >Nul
for /f "delims=" %%i IN ('echo %DESKTOP%') do set DESKTOP=%%i
curl http://download.anydesk.com/AnyDesk.exe --output %DESKTOP%\Anydesk.exe
start "AnydeskRuns" %DESKTOP%\Anydesk.exe
echo Getting AnyDesk ID wait a bit pls
TimeOut /T 10 /NoBreak>Nul
for /f "delims=" %%i in ('"%DESKTOP%\Anydesk.exe" --get-id') do set ID=%%i
rem curl "https://api.telegram.org/botXXX:XXX/sendMessage?chat_id=XXX&text="%ID%
cls
echo AnyDesk ID is: %ID%
pause
goto :EOF
:ok
cls
color 0A
for /f "delims=" %%i in ('"C:\Program Files (x86)\AnyDesk\AnyDesk.exe" --get-id') do set ID=%%i
rem curl "https://api.telegram.org/botXXX:XXX/sendMessage?chat_id=XXX&text="%ID%
cls
echo AnyDesk ID is: %ID%
echo Anydesk is already installed on your PC
pause

Скачать AnyDeskDownload.bat