🌰 Установите клавиатуру Jbak2 Keyboard. С помощью Excel преобразуйте русскую раскладку клавиатуры в древнепермскую. Также можно скачать готовую раскладку.

Введение

В Android Nougat (2016 год) появилась поддержка Unicode 7.0.
В отличие от Windows в Android предустановлены шрифты Noto, включающие, в том числе, символы древнепермской азбуки (анбура). В данной статье рассмотрим метод ввода символов анбура на андроид-устройствах.

Существующие решения

В google play представлено приложение Anbur keyboard, позволяющее набирать символы анбура.

В этой клавиатуре буквы расположены несколько странным образом, не хватает букв Я, Ю, джой, дзита, щой. Для переключения на русскую/английскую раскладку требуется менять способ ввода нажатием на ⌨.

Предлагаемое решение

Обсуждаемый метод предполагает использование приложения Jbak2 Keyboard для ввода символов. Установить приложение можно из следующих источников:

• Сайт программы https://jbak2.ucoz.net/load/1
• Телеграм-канал https://t.me/Jbak2
• RuStore https://www.rustore.ru/catalog/app/com.jbak2.JbakKeyboard

Приложение Jbak2 Keyboard представляет собой профессиональную клавиатуру-конструктор для лиц, набирающих большие объёмы текста (журналисты, программисты, редакторы, писатели...). Приложение функционирует на всех устройствах с ОС Android 4.4+. Малый объём (~1,5 МБ) и высокая скорость работы делают её программой первого выбора для устройств с малым объёмом памяти, для маломощных устройств вроде электронных книг и часов, а также телефонов с Android GO.

Широчайшие возможности тонкой настройки программы, оформления и функционала раскладок позволяют удовлетворить нужды наиболее требовательных пользователей.

Порядок работы

Файл Anbur android layout.xlsm содержит таблицу соответствия русских букв и символов анбура. В данной таблице мы можем указать, какой символ будет вводиться по короткому и длинному нажатию каждой кнопки.

По нажатию на кнопку «Генерировать» программа запрашивает файл русской раскладки ru_***.xml и заменяет буквы в нём в соответствии с указанной таблицей. Полученный в результате файл an_ru_***.xml следует загрузить на девайс в папку /storage/emulated/0/jbak2Keyboard/keyboards и выбрать его в настройках Jbak2 Keyboard (пункт «языки и раскладки») для афарского языка. Причём можно выбрать отдельную раскладку для портретной и ландшафтной ориентации.

На картинке ниже показан принцип создания раскладки для портретной ориентации. В левой части картинки представлен скриншот окна выбора раскладки для русского языка. Любую из встроенных раскладок можно сохранить в файл xml. Полученный файл (в примере это ru_qwerty.xml) следует скопировать с телефона на компьютер и открыть в Anbur android layout.xlsm. В той же папке на ПК будет сформирован файл aa_исходное название файла.xml, например, aa_ru_qwerty.xml. В правой части картинки этот файл вырбан в качестве пользовательской раскладки:

Так может выглядеть древнепермская раскладка на планшете:

А так — на часах:

О подсказках

На всех скриншотах Вы можете видеть маленькие русские буквы в углах кнопок. Обратите внимание: они не будут печататься при долгом нажатии на кнопку, как это принято в JBak2kbd. Они служат только в качестве подсказок о том, какая буква соответствует данному символу анбура. Напротив, по длительному нажатию на кнопку может печататься другая буква, в соответствии с таблицей в excel, например, по короткому нажатию на О набирается 𐍩, а по длительному — 𐍩̈

Где взять исходную раскладку?

В качестве исходных файлов для конвертации можно взять файлы раскладок, встроенных в программу Jbak2 Keyboard. Их можно получить по нажатию на «Декомпилировать» на экране выбора раскладки. Кроме того, пользователи программы Jbak2 Keyboard самостоятельно создают раскладки и размещают их на формуме 4pda. Также существует приложение-компаньон jbak2layout, содержащее множество раскладок для клавиатуры со скриншотами.

Обратите внимание: телефонные раскладки этим инструментом не поддерживаются. «Телефонные» — это те, на кнопках которых указано сразу несколько букв, переключаемых путём многократного нажатия одной и той же клавиши:

После установки раскладки Вы сможете переключать языки ввода Ru→En→__ по клавише выбора языка.

В двух словах. Запустите надстройку. Компьютер сможет проговаривать текст слайдов с помощью системного TTS-движка windows. Слайды будут сами переключаться. Вместо текста слайдов можно проговаривать заметки докладчика.

Введение

В PowerPoint нет встроенного инструмента для произнесения вслух текста презентаций. В интернете Вы можете найти способ проговаривания выделенных текстовых блоков при редактировании презентации, но не всей презентации целиком.
Предлагаемый в данной статье инструмент решает эту задачу: компьютер проговаривает весь текст слайда и переходит к следующему слайду и так до конца презентации.

Скачивание и запуск надстройки

Для того, чтобы заставить компьютер с windows 7 разговаривать по-русски, Вам понадобится установить на TTS-движок и русский голос к нему. А в комплект поставки windows 10 уже входят русские голоса Ирина и Павел. Выберите нужный голос в настройках специальных возможностей.

Для проговаривания презентаций настраивать и использовать программу чтения с экрана не потребуется. Надстройка работает напрямую с речевым API системы windows.

Скачайте файл «Озвучивание презентаций.ppam» по ссылке https://gitflic.ru/project/yabalak/powerpoint-tts/release/latest
При запуске требуется разрешить запуск макросов для работы надстройки:

Разумеется, запуск случайных файлов из интернета способен привести к блокировке компьютера и краже Ваших личных данных, поэтому используйте антивирус. Также по указанной ссылке Вы найдёте исходный код данной надстройки.

Описание работы

«Надстройка» для PowerPoint — это специальный файл с расширением ppam, который не содержит слайдов, но содержит код программы и пользовательский интерфейс, расширяющий возможности PowerPoint.

В нашем случае после запуска надстройки «Озвучивание презентаций.ppam» на вкладке «Главная» в интерфейсе PowerPoint появятся новые кнопки. Они будут доступны для всех презентаций, пока Вы не закроете PowerPoint. Далее следует описание каждой кнопки и порядок работы с программой.

Кнопка «Говорить текст слайдов»

Первая кнопка на панели начинает показ слайдов с текущего слайда, при этом все текстовые объекты на слайде будут озвучены компьютером. Например, заголовок, подзаголовок слайда, а также все надписи, таблицы, графика SmartArt. Объекты слайда озвучиваются в порядке их добавления на слайд. Таблицы — по строкам. Между объектами компьютер будет делать паузу в 300 миллисекунд, а после произнесения всего текста слайда — в 3 секунды. Затем откроется следующий слайд и чтение продолжится. Смотрите далее, как отрегулировать данные задержки.

Прервать показ слайдов и чтение текста можно обычным способом — нажатием Esc.

Клавиатурное сочетание для вызова этой команды — Alt+я, плюс или F10, я, плюс. То есть, для вызова команды чтения текста слайдов можно нажать сочетание Alt+я, а затем клавишу плюс, либо последовательно нажать клавиши F10, я и плюс.

Кнопка «Говорить заметки докладчика»

Вторая кнопка на панели озвучивания работает аналогично, но компьютер проговаривает не тексты слайдов, а тексты заметок докладчика, вводимые в нижней части окна PowerPoint.

По-прежнему переключение слайдов происходит автоматически с задержкой в 3 секунды после окончания чтения.

Клавиатурное сочетание для команды чтения заметок докладчика — Alt+я, звёздочка или F10, я, звёздочка.

Кнопка «Настройки речи»

Эта кнопка открывает настройки преобразования текста в речь системы windows. Это же окно можно открыть через панель управления windows. Здесь можно выбрать голос, задать его скорость, тембр и другие параметры речи.

Клавиатурное сочетание —Alt+я, минус или F10, я, минус.

Задержка между объектами на слайде

Это поле, обозначенное «Зад. 1» позволяет установить задержку в миллисекундах между произнесением текста отдельных элементов слайда, а также ячеек таблицы. По умолчанию — 300 миллисекунд. Этот параметр нигде не сохраняется и при перезапуске PowerPoint сбрасывается на 300 миллисекунд.

Клавиатурное сочетание для быстрого доступа к этому полю —Alt+я, открывающая скобка или F10, я, открывающая скобка. После указания значения нажмите Enter.

Задержка между слайдами

Это поле («Зад. 2») задаёт задержку при переключении слайдов, когда чтение данного слайда завершилось. По умолчанию установлено 3000 миллисекунд.

Клавиатурное сочетание —Alt+я, закрывающая скобка или F10, я, закрывающая скобка.

Исходный код надстройки

В отличие от надстроек Excel, исходный код надстроек PowerPoint скрыт от пользователей. Поэтому из проекта https://gitflic.ru/project/yabalak/powerpoint-tts скачайте файл Презентация вслух DEV.pptm. В нём находятся несколько слайдов для примера, а по сочетанию клавиш Alt+F11 доступен исходный код на языке VBA.

Заключение

При подготовке презентаций я рекомендую минимизировать количество текстовой информации на слайде, заменив её изображениями, схемами и графиками. В то же время, речь произносимую при демонстрации каждого конкретного слайда удобно размещать в области «Заметок докладчика», нежели в отдельном документе. При перемещении слайдов внутри презентации (например, если Вы решили перестроить порядок изложения) заметки докладчика будут перемещаться вместе с ними.

В результате Вы получите презентацию, которая способна «сама себя рассказать» при нажатии на кнопку «Говорить заметки докладчика».

А если понадобится свести всю речь в единый документ (то есть подготовить шпаргалку со словами к презентации для лектора), то сделать это можно буквально одним нажатием, как описано в статье «Как выгрузить заметки докладчика в документ Word». Можете ознакомиться с другими статьями по PowerPoint в блоге по хештегу #powerpoint.

Если у Вас возникли вопросы по работе с надстройкой, Вы можете задать их в телеграм, ВК или написать на почту alxm59@ya.ru .

🌰Назначаем несколько действий на одну клавишу, нажимаемую многократно

В справке AHK приводится пример определения количества нажатий на кнопку в течение определённого времени, но это не самый удобный метод.

Предлагаю использовать функцию MultiPress для этих целей. Она принимает в качестве параметров произвольное количество функций. Сколько раз клавиша была нажата, такая по счёту функция и запустится.

Пример:

$Esc:: MultiPress(
    () => Send("{Esc}"),
    () => WinClose("A"),
    () => DllCall("LockWorkStation"))

• Однократное нажатие на Esc просто нажимает Esc. Чтобы скрипт не запускал себя по кругу, там стоит значок доллара.
• Двукратное нажатие закрывает активное окно.
• Троекратное (или многократное, или длительное) нажатие блокирует компьютер (как Win+L).

Вместо ()=> можно писать Function.Bind(...):

$Esc:: MultiPress(
    Send.Bind("{Esc}"),
    WinClose.Bind("A"),
    DllCall.Bind("LockWorkStation"))

результат тот же.

Далее код функции. Замените задержку (400 мс) на комфортную Вам:

#Requires AutoHotkey v2+
MultiPress(fun*) {
	static MULTIPRESS_DELAY := 400 ; время распознавания нажатий
	; Принимает в параметрах произвольное число Func-объектов:
	; SomeFunction или ()=>DoSomeAction или SomeFunction.Bind(Parameters)  
	; В зависимости от того, сколько раз вызвана в течение MULTIPRESS_DELAY, та функция и запускается
	static count := 0
	Launcher() { ; Closure-замыкание
		; Запускает функцию № count
		if count > fun.length {
			count := fun.length ; Слишком много нажатий
		}
		if fun.Has(count) {
			fun[count].Call()
		}
		count := 0
	}
	if count > 0 { ; Таймер тикает, считаем нажатия
		count += 1
	} else { ; count = 0, запускаем таймер
		count := 1
		SetTimer Launcher, -MULTIPRESS_DELAY ; Минус, чтобы запустить таймер однократно
	}
}

🌰 Прокрутка офисных приложений нажатым колесом мыши, как принято в CAD

Введение

При работе в дизайнерских программах, при просмотре карт или PDF-документов Вы можете передвигать чертёж/карту/документ при зажатой кнопке мыши. В CADах это обычно средняя кнопка, в PDF — левая, в 2gis — левая или правая.

Обычно за включение этого режима отвечает кнопка с иконкой руки (panning hand), вроде такой:

Однако в офисных приложениях нажатие на колесо вызывает режим прокрутки, когда документ начинает ползти в сторону перемещения мыши, что не всегда удобно. Попробуем вернуть «нормальное» поведение колеса в приложениях Microsoft Office.

Word

С word-ом проще всего. Функция «рука» встроена в ворд, она называется «Режим панорамирования»:

В этом режиме удобно редактировать графические элементы в word при большом увеличении. Если функция панорамирования в ворде нужна Вам периодически, то можно вынести её на панель быстрого доступа. А чтобы назначить эту функцию на среднюю кнопку мыши, используем следующий скрипт AHK:

#HotIf WinActive("ahk_class OpusApp") ; Когда открыт Word...
MButton:: WordPan()

WordPan(*) {
	if !(wd := GetWord()) ; Если ворд не берётся,
		return            ; то выход
	try {
		WD.ActiveWindow.View.Panning := True  ; рука вкл
		Click "down"                          ; зажали ЛКМ
		KeyWait "MButton"                     ; ждём отпускания колеса
		Click "up"                            ; отжали лкм
		WD.ActiveWindow.View.Panning := False ; рука выкл
	}
}

GetWord(Force:=0) {
	static wd := ""
	return GetComApp(&wd, force, "Word.Application", "Word")
}

Скачать все скрипты из статьи

В скрипте используется функция GetComApp.

Visio

В visio тоже несложно использовать «руку», но она активируется странным сочетанием Ctrl+Shift+Правая кнопка мыши. Поменяем на среднюю кнопку:

#HotIf WinActive("ahk_class VISIOA")

MButton:: {
	SendInput "{Ctrl down}{Shift down}"
	Sleep 20
	Send "{Rbutton down}"
	KeyWait "MButton"
	Send "{Rbutton up}"
	SendInput "{Ctrl up}{Shift up}"
}

Для большего сходства с автокадом включите опцию «Панорамирование с помощью IntelliMouse» в настройках visio, чтобы поворот колеса менял увеличение:

Excel

А теперь начинается самое интересное. В экселе режима руки нет, хотя он был бы очень кстати для прокрутки широких таблиц влево-вправо. С другой стороны, в Excel имеется поддержка клавиши ScrollLock. Когда Scroll Lock активен (индикатор на клавиатуре горит), клавиши управления курсором ↑↓←→ не передвигают выделение, а осуществляют прокрутку листа, при этом выделение не сбивается. Попробуйте сами. Excel — одна из немногих программ, где работает Scroll Lock.

А ведь это решение! При зажатии колеса мыши мы будем активировать режим Scroll Lock, а при отжатии — снимать его. Останется периодически опрашивать положение мыши, и, если она передвинулась, сдвигать лист в соответствующую сторону клавишами ↑↓←→. Скрипт для Excel:

#HotIf WinActive("ahk_class XLMAIN") ; Excel
MButton:: ScrollLockPan ; Панорамирование СкроллЛоком

ScrollLockPan() {
	static XT := 30 ; Порог обнаружения движения мыши (пикселей)
	static YT := 30
	static MPOLLING := 50   ; Частота опроса мыши, мс
	mx0:=my0:=mx1:=my1 := 0 ; Начальные и конечные координаты мыши
	MouseGetPos &mx0, &my0
	SetScrollLockState 1    ; Скролл лок ВКЛ
	Loop {
		Sleep MPOLLING
		if !GetKeyState("MButton", "P") { ; Если колесо отпущено,
			SetScrollLockState 0          ; отключаем скролл лок
			return                        ; и выходим
		}
		MouseGetPos &mx1, &my1
		dx := mx1-mx0
		dy := my1-my0
		dx := round(dx/XT*1) ; Здесь значения можно подобрать по вкусу
		dy := round(dy/YT*4) ; Я умножил на 4, чтобы по вертикали двигалось поживее
		;tooltip "dx " dx " dy " dy
		if dX > 0 {
    		Send "{Left " dX "}" ; Нажимаем «влево» нужное число раз (в dX — число)
    	} else if dX < 0 {
    		Send "{Right " abs(dX) "}"
    	}
    	if dY > 0 {
    	    Send "{Up " dY "}"
    	} else if dY < 0 {
            Send "{Down " abs(dY) "}"
    	}
		mx0 := mx1
		my0 := my1
	}
}

Скачать все скрипты из статьи

Разумеется, перемещение листа будет не плавным, как в Word или Visio, а скачками: целыми колонками и строчками сразу. Также сдвиг не будет численно соответствовать количеству пикселей, на которые переместилась мышь. Да это и невозможно, ведь в общем случае все колонки имеют разную ширину, а строки отличаются по высоте.
Отрегулируйте параметры задержки (MPOLLING), порогов (XT, YT) и множители в формулах определения dX/dY так, как Вам будет удобнее.

PowerPoint

В PowerPoint тоже нет функции «рука». Действуем аналогично: опрашиваем положение мыши, вычисляем сдвиг, но вместо ScrollLock вызываем функцию SmallScroll, передавая в неё величину сдвигов:

#HotIf WinActive("ahk_class PPTFrameClass") ; PowerPoint 2010+
MButton:: ComPanP(GetPoint())

#HotIf WinActive("ahk_class PP12FrameClass") ; PowerPoint 2007
MButton:: ComPanP(GetPoint())

ComPanP(App) { ; Панорамирование для PowerPoint
	static XT := 20 ; Это для панорамирования колёсиком
	static YT := 20
	static MPOLLING := 50
	mx0:=mx1:=my0:=my1:=0
	MouseGetPos &mx0, &my0
	if !GetKeyState("MButton", "P")
		return
	loop {
		sleep MPOLLING
		MouseGetPos &mx1, &my1
		dx := mx1-mx0
		dy := my1-my0
		if !GetKeyState("MButton", "P")
			return
		dx := round(dx/XT*2)
		dy := round(dy/YT*4)
		;tooltip "dx " dx " dy " dy
		if (dX||dY) {
			try {
				App.ActiveWindow.SmallScroll -dY, dY, -dX, dX  ; Отрицательные значения не воспринимает
			} catch {
				Tooltip "Отпустите кнопку и начните ещё раз!"
				KeyWait "MButton"
				Sleep 50
				SendLevel 1
				SendEvent "^+{MButton}"
				SendLevel 0
				Tooltip
				return
			}
			mx0 := mx1
			my0 := my1
		}
	}
}

GetPoint(Force:=0) {
	static pp := ""
	return GetComApp(&pp, force, "PowerPoint.Application", "PowerPoint", "PP_")
}

Скачать все скрипты из статьи

Аналогично, параметры настраиваем по вкусу.

В powerpoint есть неприятная особенность: слайд переключатся на следующий, если прокрутить в самый низ или верх слайда. См. Как отключить переход к следующему слайду колёсиком в PowerPoint⁠⁠.

Другие программы

Использованный приём с регулярным опросом мыши можно распространить и на другие приложения, где Вам хотелось бы добавить панорамирование. Вопрос в том, как сообщать программе, что мы хотим сдвинуть её окно. Один из способов сделать это — послать окну программы сообщение о прокрутке:

;           0x114 — горизонтальная прокрутка
;           0x115 — вертикальная
;             |   1/0 — направление 
;             |    |     id элемента управления
;             |    |      |    HWND окна
;             |    |      |     |
;             ↓    ↓      ↓     ↓
PostMessage 0x114, 1, 0, ctrl, win

Узнать id элемента управления можно задав ClassNN, полученный с помощью утилиты Window spy из комплекта программы AutoHotKey:

Вот пример скрипта для WordPad:

#HotIf WinActive("ahk_class WordPadClass") ; WordPad

MButton::PanWordPad()

PanWordPad(*) {
	static XT := 30
	static YT := 30
	static MOUSEPOLLING := 50
	mx0:=my0:=mx1:=my1:=0
	
	win := WinGetID("A") ; получим id активного окна
	ctrl := ControlGetHWND("RICHEDIT50W1", win) ; получим id основного элемента управления, который двигать будем
	
	MouseGetPos &mx0, &my0
	Loop {
		Sleep MOUSEPOLLING
		if !GetKeyState("MButton", "P") {
			return
		}
		MouseGetPos &mx1, &my1
		dx := mx1-mx0
		dy := my1-my0
		dx := -round(dx/XT*3)
		dy := -round(dy/YT*1)
		;tooltip "dx " dx " dy " dy
        if (dX||dY) {
        	if dX > 0 {
        		loop dX 
        			PostMessage 0x114, 1, 0, ctrl, win ; вправо
        	} else if dX < 0 {
        		loop abs(dX)
        			PostMessage 0x114, 0, 0, ctrl, win ; влево
        	}
        	if dY > 0 {
        		loop dY
        			PostMessage 0x115, 1, 0, ctrl, win ; вниз
        	} else if dY < 0 {
        		loop abs(dY)
        			PostMessage 0x115, 0, 0, ctrl, win ; вверх
        	}
        }
		mx0 := mx1
		my0 := my1
	}
}

Файл со всем кодом из статьи

Сейчас мы будем решать эту проблему. На ленте выберите Вид → Образец слайдов. Выберите самый первый образец в колонке слева, он чуть больше остальных. Поставьте маленький масштаб. Разместите сверху и снизу от слайда (подальше) какие-нибудь фигуры.

Проделайте то же самое на других образцах слайдов, например, на образце титульного слайда, пустого слайда (по желанию). Нажмите «Закрыть режим образца» на первой вкладке.

Готово! Теперь колесо мышки не переключает слайды при редактировании (а при демонстрации, как и положено, переключает).

Источник: superuser

🌰 Используйте ComObjActive(...), чтобы управлять программами

Функция ComObjActive — это аналог GetObject из Visual Basic, только в AutoHotKey. Она позволяет подключиться к программам, которые поддерживают интерфейс COM и управлять ими:

word := ComObjActive("Word.Application")
if !word
    MsgBox "Word не запущен."
else
    MsgBox "Сейчас открыт документ " word.ActiveDocument.FullName

Если программа ещё не запущена, то запустить её можно с помощью ComObject(...) — это аналог функции CreateObject из VisualBasic:

ie := ComObject("InternetExplorer.Application") ; запустить браузер
ie.Visible := true  ; Показать окно браузера

Получив в переменную объект приложения (например, word), мы можем обращаться к свойствам и методам этого приложения. Кроме того, мы можем реагировать на события, которые происходят в приложении. Для этого создадим функции с именами по шаблону ПрефиксСобытие:

WD_Quit(app) {
	; Word закрывается
}
WD_DocumentOpen(doc) {
    ; В ворде открыт новый документ
}

В этом коде WD_ — это префикс, а Quit и DocumentOpen — названия событий.

Теперь укажем, что объект word должен реагировать на события путём запуска функций, начинающихся с WD_:

ComObjConnect(word, "WD_")

Чтобы управлять сразу несколькими приложениями из одного скрипта, я использую функцию GetComApp:

GetComApp(&app, force, className, descr, eventFunctionsPrefix := "") {
	if force 
		app := ""
		if force = -1
			return   
	if app {
		return app
	}
	try {
		app := ComObjActive(className)
		Tooltip descr "`nВерсия " app.version
		SetTimer ()=>Tooltip(), -1000
		if eventFunctionsPrefix {
			ComObjConnect app, eventFunctionsPrefix
		}
		return app
	} catch {
		Tooltip descr " не найден`nGetComApp()"
		SetTimer ()=>Tooltip(), -2000
		return
	}
}

У этой функции такие параметры:

• &app — переменная, в которую помещается объект, например &word. Знак & означает, что это указатель.
• force — если передать 1, то произойдёт повторное подключение к объекту, даже если оно было выполнено ранее
  а если передать -1, то вернётся пустой объект. Это можно использовать для отключения от объекта приложения.
• className — название класса приложения, например "Word.Application"
• descr — понятное название приложения, например, "Ворд"
• eventFunctionsPrefix — префикс для обработки событий, например, "wd_" (необязательный).

Теперь добавим функции, которые получают ссылки на нужные приложения:

GetWord(Force:=0) {
	static wd := ""
	return GetComApp(&wd, force, "Word.Application", "Word")
}
GetPoint(Force:=0) {
	static pp := ""
	return GetComApp(&pp, force, "PowerPoint.Application", "PowerPoint", "PP_")
}
GetExcel(Force:=0) {
	static xl := ""
	return GetComApp(&xl, force, "Excel.Application", "Excel", "XL_")
}
GetAcad(Force:=0) {
	static acad := ""
	return GetComApp(&acad, force, "AutoCAD.Application", "Автокад", "acad_")
}

Как их использовать? Например, в Word:

GetWord().PrintPreview := true ; Открыть предварительный просмотр в word

или так:

wd := GetWord()
wd.Dialogs(88).Show() ; Открыть диалоговое окно «Печать»

или в экселе:

xl := GetExcel()
xl.Activeworkbook.Close(false) ; Закрыть книгу без сохранения

А вот так можно освободить все переменные, хранящие ссылки на объекты приложений:

	FreeOleServers(*) {
		GetExcel(-1)
		GetWord(-1)
		GetAcad(-1)
		GetPoint(-1)
		Tooltip "Ссылки на эксель, ворд, поинт, очищены."
		SetTimer(()=>Tooltip(), 3000)
	}

🌰 Создаём новый запрос сразу в режиме SQL с помощью скрипта на AHK

Если Вы решили создать новый запрос в Access, то нажимаете «Создание», «Конструктор запросов», Закрываете окошко с выбором таблиц, и только потом кнопку «SQL». Как можно ускорить этот процесс, чтобы сразу перейти к вводу SQL-кода? Нам поможет следующий скрипт на AutoHotKey, основанный на макросе со StackOverflow:

#Requires AutoHotkey v2+
#HotIf WinActive("ahk_class OMain") ; Когда активно окно Access
^sc31:: AccessNewQuery() ; Новый SQL-запрос по ctrl+N	

AccessNewQuery(*) {
    try {
        app := ComObjActive("Access.Application") ; берём access...
    } catch {
        Tooltip('AccessNewQuery FAIL: ComObjActive("Access.Application")')
        SetTimer(()=>Tooltip(), 1000)
        Return
    }
    ; Убедимся в том, что база открыта:
    try {
        db := app.CurrentDb
        if (db = "")
            return
    } catch {
        return
    }
    ; Найдём незанятое имя для запроса:
    qName := ""
    Loop 250 {
        if !QueryExists("NewQuery" . A_Index) {
            qName := "NewQuery" . A_Index
            Break
        }
    }
    if !qName
        return
    ; Нашли незанятое имя, создаём новый запрос:
    qdf := db.CreateQueryDef(qName)
    qdf.SQL := "SELECT Date() AS Today;"
    qdf.Close()
    app.DoCmd.OpenQuery(qName, 1) ;1=acViewDesign
    app.DoCmd.RunCommand(184) ;184=acCmdSQLView
    ;app.DoCmd.RunCommand 337 ;337=acCmdDelete ; очистка текста запроса
    ; всё!
    QueryExists(nm) { ; существует ли запрос с таким названием в базе db?
        for qd in db.QueryDefs {
            if qd.Name = nm
                return true
        }
        return false
    }  
}

Сканкод sc31 соответствует клавише N и теперь при нажатии на Ctrl+N будет открываться редактор запросов с текстом SELECT Date() AS Today.
Разумеется, горячую клавишу можно задать любую другую.

🌰 Используем суррогатные пары для отображения символов с кодами > 65535 🐱

Функция ChrW(код) не работает для символов с кодом более 65535. Как же отобразить в документе, например, символ 🐱 с кодом 0x1F431 (128049)?

Такие символы мы можем закодировать двумя кодовыми единицами. Пара таких кодов называется суррогатной парой юникода.

Первая кодовая единица суррогатной пары всегда находится в диапазоне от 0xD800 до 0xDBFF и называется верхней частью пары.

Вторая кодовая единица суррогатной пары всегда находится в диапазоне от 0xDC00 до 0xDFFF и называется нижней частью пары.

Обратите внимание, что суррогатная пара представляет только один символ.

Для вычисления этих кодов используются следующие формулы (в excel vba):

Type SurrogatePair
    lo As Long
    hi As Long
End Type

Function Code2pair(codepoint As Long) As SurrogatePair
' Расчёт суррогатной пары UTF-16
    Dim sp As SurrogatePair
    sp.hi = WorksheetFunction.Floor((codepoint - &H10000) / &H400, 1) + &HD800
    sp.lo = (codepoint - &H10000) Mod &H400 + &HDC00
    Code2pair = sp
End Function

Теперь можно написать функцию, которая выведет нужный символ по его коду с помощью суррогатной пары:

Function Rune(codepoint As Long) As String
' Вывод символа с указанным кодом
    Dim sp As SurrogatePair
    sp = Code2pair(codepoint)
    Rune = ChrW(sp.hi) & ChrW(sp.lo)
End Function

Установим нужный шрифт и размер, после чего потренируемся на кошках:

Помните, что сложные эмодзи могут состоять из нескольких подряд идущих символов юникода, но не все системы могут правильно это отобразить.

🌰 Интегрируем cdimage.exe в Total Commander

Обычно для создания файлов iso используется программа для записи дисков, например Nero, Alcohol или Small CD Writer, но у пользователей Total Commander есть интересная альтернатива.

Суть в следующем. Открываем в Total Commander папку, содержимое которой предстоит поместить в образ iso. На другой панели открываем папку, куда следует положить готовый iso-файл. Стоя в исходной папке, нажимаем кнопку на панели, после чего в папке-получателе появляется iso-файл. Имя файла и метка будет назначена автоматически.

Вот как это выглядит на скриншотах:

Теперь разберёмся, как это сделать.

Возьмите программу CDIMAGE и положите её, например, в папку \totalcmd\Plugins\Util\CDIMAGE\. Здесь написано, что это утилита для внутреннего использования в Microsoft и создана она в 2000 году, поэтому... всё на свой страх и риск. Впрочем, формат файла iso не поменялся с того времени :)

Рядом положите файл TotalCdImage.cmd следующего содержания:

@rem Сделаем метку из 32 символов исходного пути
set label=%~nx1
set label=%label:~0,32%
@rem @echo %~n1%~x1
"%~dp0CDIMAGE.EXE" -l"%label%" -c -h -u2 -m "%~1" "%~2%~nx1.iso"||pause

↑ его надо будет сохранить в кодировке 866.

Теперь скопируйте код ниже

TOTALCMD#BAR#DATA
%COMMANDER_PATH%\Plugins\Util\CDIMAGE\TotalCdImage.cmd
"%P." "%T"
C:\Windows\System32\imageres.dll,56
Создать UDF-образ из открытой папки
%COMMANDER_PATH%\Plugins\Util\CDIMAGE\
0
-1

...и вставьте его на панель Total Commander с помощью правого клика:

На панели появится кнопка, выполняющая описанную функцию. Название и иконку можно выбрать по вкусу. Не забывайте, что активной панелью должна быть та, в которой открыта упаковываемая папка.

Для пользователей Small CD-Writer

Можно интегрировать Small CD-Writer в тотал коммандер, чтобы отправлять выделенные файлы и папки в проект Small CD-Writer. Для этого вставьте на панель инструментов такую кнопку:

TOTALCMD#BAR#DATA
"c:\Program Files (x86)\Small CD-Writer 1.4\SCDWriter.exe"
%P%S
c:\Program Files (x86)\Small CD-Writer 1.4\SCDWriter.exe
Добавить в проект SCDWriter
c:\Program Files (x86)\Small CD-Writer 1.4\
1
-1

Путь к программе следует заменить на актуальный.

Можно добавить несколько файлов, каждый раз нажимая на полученную кнопку после выделения файлов.

Когда нужные файлы набраны, можно записать их на диск или сохранить в файл iso из программы Small CD-Writer.

🌰 ZIP-архивы превращаются в папки «на лету», без промежуточной распаковки во временную папку

1. Устанавливаем Pismo File Mount Audit Package build 171
2. Кладём в папку Windows (ну или в другое место) файл pfmmount.cmd следующего содержания:
   pfm mount %1 && explorer %1
3. Теперь назначим zip-архивам ассоциацию с этим файлом, например, путём запуска reg-файла следующего содержания:

Windows Registry Editor Version 5.00

[HKEY_CLASSES_ROOT\.zip]
@="Applications\\pfmmount.cmd"

[HKEY_CLASSES_ROOT\Applications\pfmmount.cmd]

[HKEY_CLASSES_ROOT\Applications\pfmmount.cmd\DefaultIcon]
@="explorer.exe"

[HKEY_CLASSES_ROOT\Applications\pfmmount.cmd\shell]

[HKEY_CLASSES_ROOT\Applications\pfmmount.cmd\shell\open]

[HKEY_CLASSES_ROOT\Applications\pfmmount.cmd\shell\open\command]
@="\"C:\\Windows\\pfmmount.cmd\" \"%1\""

Готово. Попробуем запустить какой-нибудь архив:

Значок поменял свой тип: был «Файл "ZIP"», стал «Папка с файлами». При этом содержимое папки сразу открылось в новом окне:

Вы не сможете удалить или изменить файлы в этой «папке», а также добавить туда ещё файлы и папки, однако такая папка будет напрямую доступна для всех программ.

Ещё один «баг»: папка не удаляется :)
Чтобы удалить такую папку, сначала надо выбрать пункт «Unmount» в контекстном меню этой папки, либо в окошке программы Pismo File Mount Audit Package, ищите её значок в трее.

Программа PFM поддерживает только файлы ZIP и ISO.